dev-util/gnome-builder/gnome-builder-3.30.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python3_{5,6} )
   6 VALA_MIN_API_VERSION="0.36"
   7 DISABLE_AUTOFORMATTING=1
   8 FORCE_PRINT_ELOG=1
   9
  10 inherit gnome.org gnome2-utils llvm meson python-single-r1 readme.gentoo-r1 vala virtualx xdg
  11
  12 DESCRIPTION="An IDE for writing GNOME-based software"
  13 HOMEPAGE="https://wiki.gnome.org/Apps/Builder"
  14
  15 # FIXME: Review licenses at some point
  16 LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
  17 SLOT="0"
  18 KEYWORDS="amd64 ~x86"
  19 IUSE="clang +devhelp doc +git gtk-doc sysprof test vala webkit"
  20 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  21
  22 # When bumping, pay attention to all the included plugins/*/meson.build (and other) build files and the requirements within.
  23 # `grep -rI dependency * --include='meson.build'` can give a good initial idea for external deps and their double checking.
  24 # The listed RDEPEND order shold roughly match that output as well, with toplevel one first.
  25 # Most plugins have no extra requirements and default to enabled; we need to handle the ones with extra requirements. Many of
  26 # them have optional runtime dependencies, for which we try to at least notify the user via DOC_CONTENTS (but not all small
  27 # things); `grep -rI -e 'command-pattern.*=' -e 'push_arg'` can give a (spammy) idea, plus python imports in try/except.
  28
  29 # FIXME: with_flatpak needs flatpak.pc >=0.8.0, ostree-1, libsoup-2.4.pc >=2.52.0 and ${LIBGIT_DEPS}
  30 # Editorconfig needs old pcre, with vte migrating away, might want it optional or ported to pcre2?
  31 # An introspection USE flag of a dep is required if any introspection based language plugin wants to use it (grep for gi.repository). Last full check at 3.28.4
  32
  33 # These are needed with either USE=git or USE=flatpak (albeit the latter isn't supported yet)
  34 LIBGIT_DEPS="
  35         dev-libs/libgit2[ssh,threads]
  36         >=dev-libs/libgit2-glib-0.25.0[ssh]
  37 "
  38 # TODO: Handle llvm slots via llvm.eclass; see plugins/clang/meson.build
  39 RDEPEND="
  40         >=dev-libs/libdazzle-3.30.2[introspection,vala?]
  41         >=dev-libs/glib-2.58.0:2
  42         >=x11-libs/gtk+-3.24.0:3[introspection]
  43         >=x11-libs/gtksourceview-4.0.0:4[introspection]
  44         >=dev-libs/json-glib-1.2.0
  45         >=dev-libs/jsonrpc-glib-3.30.1[vala?]
  46         >=x11-libs/pango-1.38.0
  47         >=dev-libs/libpeas-1.22.0[python,${PYTHON_USEDEP}]
  48         >=dev-libs/template-glib-3.28.0[introspection,vala?]
  49         >=x11-libs/vte-0.40.2:2.91[vala?]
  50         >=dev-libs/libxml2-2.9.0
  51         git? ( ${LIBGIT_DEPS} )
  52         dev-libs/libpcre:3
  53         webkit? ( >=net-libs/webkit-gtk-2.12.0:4=[introspection] )
  54
  55         >=dev-libs/gobject-introspection-1.48.0:=
  56         >=dev-python/pygobject-3.22.0:3[${PYTHON_USEDEP}]
  57         ${PYTHON_DEPS}
  58         clang? ( sys-devel/clang:= )
  59         devhelp? ( >=dev-util/devhelp-3.25.1:= )
  60         sysprof? ( >=dev-util/sysprof-3.30.2[gtk] )
  61         vala? (
  62                 dev-lang/vala:=
  63                 $(vala_depend)
  64         )
  65 " # We use subslot operator dep on vala in addition to $(vala_depend), because we have _runtime_
  66 #   usage in vala-pack plugin and need it rebuilt before removing an older vala it was built against
  67 # TODO: runtime ctags path finding..
  68 # FIXME: spellcheck plugin temporarily disabled due to requiring enchant-2
  69 #       >=app-text/gspell-1.2.0
  70 #       >=app-text/enchant:2
  71
  72 # desktop-file-utils required for tests, but we have it in deptree for xdg update-desktop-database anyway, so be explicit and unconditional
  73 # appstream-glib needed for validation with appstream-util with FEATURES=test
  74 DEPEND="${RDEPEND}
  75         doc? ( dev-python/sphinx )
  76         test? (
  77                 dev-libs/appstream-glib
  78                 sys-apps/dbus )
  79         dev-util/desktop-file-utils
  80         dev-util/glib-utils
  81         >=dev-util/meson-0.47.1
  82         >=sys-devel/gettext-0.19.8
  83         virtual/pkgconfig
  84 "
  85
  86 DOC_CONTENTS='gnome-builder can use various other dependencies on runtime to provide
  87 extra capabilities beyond these expressed via USE flags. Some of these
  88 that are currently available with packages include:
  89
  90 * dev-util/uncrustify and dev-python/autopep8 for various Code Beautifier
  91   plugin out of the box functionality.
  92 * dev-util/ctags with exuberant-ctags selected via "eselect ctags" for
  93   C, C++, Python, JavaScript, CSS, HTML and Ruby autocompletion, semantic
  94   highlighting and symbol resolving support.
  95 * dev-python/jedi and dev-python/lxml for more accurate Python
  96   autocompletion support.
  97 * dev-util/valgrind for integration with valgrind.
  98 * dev-util/meson for integration with the Meson build system.
  99 * dev-util/cargo for integration with the Rust Cargo build system.
 100 * dev-util/cmake for integration with the CMake build system.
 101 * net-libs/nodejs[npm] for integration with the NPM package system.
 102 '
 103 # FIXME: Package gnome-code-assistance and mention here, or maybe USE flag and default enable because it's rather important
 104 # eslint for additional diagnostics in JavaScript files (what package has this? At least something via NPM..)
 105 # jhbuild support
 106 # rust language server via rls; Go via go-langserver
 107 # autotools stuff for autotools plugin; gtkmm/autoconf-archive for C++ template
 108 # gjs/gettext/mono/PHPize stuff, but most of these are probably installed for other reasons anyways, when needed inside IDE
 109
 110 llvm_check_deps() {
 111         has_version "sys-devel/clang:${LLVM_SLOT}"
 112 }
 113
 114 pkg_setup() {
 115         python-single-r1_pkg_setup
 116         use clang && llvm_pkg_setup
 117 }
 118
 119 src_prepare() {
 120         use vala && vala_src_prepare
 121         xdg_src_prepare
 122 }
 123
 124 src_configure() {
 125         local emesonargs=(
 126                 -Denable_tracing=false
 127                 -Denable_profiling=false # not passing -pg to CFLAGS
 128                 -Dfusermount_wrapper=false # meant for flatpak builds
 129                 -Dwith_tcmalloc=false
 130                 -Dwith_channel=other
 131                 -Dwith_editorconfig=true # needs libpcre
 132                 $(meson_use webkit with_webkit)
 133                 $(meson_use vala with_vapi)
 134                 $(meson_use doc with_help)
 135                 $(meson_use gtk-doc with_docs)
 136
 137                 -Dnetwork_tests=false
 138                 $(meson_use clang with_clang)
 139                 $(meson_use devhelp with_devhelp)
 140                 -Dwith_deviced=false
 141                 -Dwith_flatpak=false
 142                 $(meson_use git with_git)
 143                 $(meson_use webkit with_html_preview)
 144                 -Dwith_spellcheck=false # TODO: requires enchant-2
 145                 $(meson_use sysprof with_sysprof)
 146                 $(meson_use vala with_vala_pack)
 147         )
 148         meson_src_configure
 149 }
 150
 151 src_install() {
 152         meson_src_install
 153         if use doc; then
 154                 rm "${ED}"/usr/share/doc/gnome-builder/en/.buildinfo || die
 155                 rm "${ED}"/usr/share/doc/gnome-builder/en/objects.inv || die
 156                 rm -r "${ED}"/usr/share/doc/gnome-builder/en/.doctrees || die
 157                 # custom docdir in build system, blocked by https://github.com/mesonbuild/meson/issues/825
 158                 mv "${ED}"/usr/share/doc/gnome-builder/en "${ED}"/usr/share/doc/${PF}/html || die
 159                 # _sources subdir left in on purpose, as HTML links to the rst files as "View page source". Additionally default docompress exclusion of /html/ already ensures they aren't compressed, thus linkable as-is.
 160                 rmdir "${ED}"/usr/share/doc/gnome-builder/ || die
 161         fi
 162         readme.gentoo_create_doc
 163 }
 164
 165 pkg_postinst() {
 166         xdg_pkg_postinst
 167         gnome2_icon_cache_update
 168         gnome2_schemas_update
 169         readme.gentoo_print_elog
 170 }
 171
 172 pkg_postrm() {
 173         xdg_pkg_postrm
 174         gnome2_icon_cache_update
 175         gnome2_schemas_update
 176 }
 177
 178 src_test() {
 179         # FIXME: can't run meson_src_test together with virtx or dbus-run-session
 180         virtx dbus-run-session meson test -C "${BUILD_DIR}"
 181 }