dev-util/gdbus-codegen/gdbus-codegen-2.52.3.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GNOME_ORG_MODULE="glib"
   6 PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
   7 PYTHON_REQ_USE="xml"
   8
   9 inherit gnome.org distutils-r1
  10
  11 DESCRIPTION="GDBus code and documentation generator"
  12 HOMEPAGE="https://www.gtk.org/"
  13
  14 LICENSE="LGPL-2+"
  15 SLOT="0"
  16 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
  17 IUSE=""
  18
  19 RDEPEND="${PYTHON_DEPS}"
  20 DEPEND="${RDEPEND}"
  21
  22 # To prevent circular dependencies with glib[test]
  23 PDEPEND=">=dev-libs/glib-${PV}:2"
  24
  25 S="${WORKDIR}/glib-${PV}/gio/gdbus-2.0/codegen"
  26
  27 python_prepare_all() {
  28         PATCHES=(
  29                 "${FILESDIR}/${PN}-2.40.0-sitedir.patch"
  30         )
  31         distutils-r1_python_prepare_all
  32
  33         sed -e 's:#!@PYTHON@:#!/usr/bin/env python:' gdbus-codegen.in > gdbus-codegen || die
  34         cp "${FILESDIR}/setup.py-2.32.4" setup.py || die "cp failed"
  35         sed -e "s/@PV@/${PV}/" -i setup.py || die "sed setup.py failed"
  36 }
  37
  38 src_test() {
  39         einfo "Skipping tests. This package is tested by dev-libs/glib"
  40         einfo "when merged with FEATURES=test"
  41 }
  42
  43 python_install_all() {
  44         distutils-r1_python_install_all # no-op, but prevents QA warning
  45         doman "${WORKDIR}/glib-${PV}/docs/reference/gio/gdbus-codegen.1"
  46 }