dev-util/eric/eric-19.11-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7 PYTHON_REQ_USE="sqlite,xml"
   8 inherit python-single-r1 xdg
   9
  10 MY_P=${PN}6-${PV}
  11
  12 DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
  13 HOMEPAGE="https://eric-ide.python-projects.org/"
  14 SRC_URI="mirror://sourceforge/eric-ide/${PN}6/stable/${PV}/${MY_P}.tar.gz"
  15
  16 LICENSE="GPL-3"
  17 SLOT="6"
  18 KEYWORDS="~amd64 ~x86"
  19 IUSE="spell"
  20
  21 DEPEND="
  22         ${PYTHON_DEPS}
  23         $(python_gen_cond_dep '
  24                 >=dev-python/PyQt5-5.12[gui,help,network,printsupport,sql,svg,widgets,${PYTHON_MULTI_USEDEP}]
  25                 dev-python/PyQtWebEngine[${PYTHON_MULTI_USEDEP}]
  26                 dev-python/qscintilla-python[${PYTHON_MULTI_USEDEP}]
  27                 dev-python/sip[${PYTHON_MULTI_USEDEP}]
  28         ')
  29 "
  30 RDEPEND="${DEPEND}
  31         $(python_gen_cond_dep '
  32                 >=dev-python/chardet-3.0.4[${PYTHON_MULTI_USEDEP}]
  33                 >=dev-python/pygments-2.3.1[${PYTHON_MULTI_USEDEP}]
  34                 spell? ( dev-python/pyenchant[${PYTHON_MULTI_USEDEP}] )
  35         ')
  36 "
  37 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  38
  39 S=${WORKDIR}/${MY_P}
  40
  41 DOCS=( eric/docs/{changelog,README.rst,README-eric6-doc.rst,README-passive-debugging.rst,THANKS} )
  42
  43 src_prepare() {
  44         default
  45
  46         # Delete internal copies of dev-python/chardet and dev-python/pygments
  47         rm -fr eric/eric6/ThirdParty/{CharDet,Pygments} || die
  48 }
  49
  50 src_install() {
  51         yes n | "${PYTHON}" install.py \
  52                 -b "${EPREFIX}/usr/bin" \
  53                 -d "$(python_get_sitedir)" \
  54                 -i "${D}" \
  55                 -c \
  56                 -z \
  57                 || die
  58
  59         python_optimize
  60         einstalldocs
  61 }