dev-util/eric/eric-18.03.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MY_P=${PN}6-${PV}
   7 PYTHON_COMPAT=( python3_6 )
   8 PYTHON_REQ_USE="sqlite,xml"
   9 inherit python-single-r1 xdg-utils
  10
  11 DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
  12 HOMEPAGE="https://eric-ide.python-projects.org/"
  13 SRC_URI="mirror://sourceforge/eric-ide/${PN}6/stable/${PV}/${MY_P}.tar.gz"
  14
  15 LICENSE="GPL-3"
  16 SLOT="6"
  17 KEYWORDS="~amd64 ~ppc64 ~x86"
  18 IUSE=""
  19
  20 DEPEND="
  21         ${PYTHON_DEPS}
  22         $(python_gen_cond_dep '
  23                 >=dev-python/sip-4.14.3[${PYTHON_MULTI_USEDEP}]
  24                 >=dev-python/PyQt5-5.7.1[gui,network,printsupport,sql,svg,widgets,${PYTHON_MULTI_USEDEP}]
  25                 >=dev-python/qscintilla-python-2.10[qt5(+),${PYTHON_MULTI_USEDEP}]
  26         ')
  27 "
  28 RDEPEND="${DEPEND}
  29         $(python_gen_cond_dep '
  30                 || (
  31                         dev-python/PyQt5[help,webengine,${PYTHON_MULTI_USEDEP}]
  32                         dev-python/PyQt5[help,webkit,${PYTHON_MULTI_USEDEP}]
  33                 )
  34                 >=dev-python/chardet-3.0.4[${PYTHON_MULTI_USEDEP}]
  35                 >=dev-python/coverage-4.1.0[${PYTHON_MULTI_USEDEP}]
  36                 >=dev-python/pygments-2.2.0[${PYTHON_MULTI_USEDEP}]
  37         ')
  38         !dev-util/eric:4
  39         !dev-util/eric:5
  40 "
  41 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  42
  43 S=${WORKDIR}/${MY_P}
  44
  45 DOCS=( changelog README.rst THANKS )
  46
  47 src_prepare() {
  48         default
  49
  50         # Delete internal copies of dev-python/chardet and dev-python/pygments
  51         rm -fr eric/ThirdParty/{CharDet,Pygments} || die
  52
  53         # Delete internal copy of dev-python/coverage
  54         rm -fr eric/DebugClients/Python{,3}/coverage || die
  55         sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
  56                 $(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
  57 }
  58
  59 src_install() {
  60         "${PYTHON}" install.py \
  61                 -b "${EPREFIX}/usr/bin" \
  62                 -d "$(python_get_sitedir)" \
  63                 -i "${D}" \
  64                 -c \
  65                 -z \
  66                 || die
  67
  68         python_optimize
  69         einstalldocs
  70 }
  71
  72 pkg_postinst() {
  73         xdg_desktop_database_update
  74
  75         if ! has_version dev-python/enchant; then
  76                 elog "You might want to install dev-python/pyenchant for spell checking."
  77         fi
  78 }
  79
  80 pkg_postrm() {
  81         xdg_desktop_database_update
  82 }