dev-util/emilpro/emilpro-3-r2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit cmake-utils eutils
   8
   9 DESCRIPTION="a graphical disassembler for a large number of instruction sets"
  10 HOMEPAGE="http://www.emilpro.com/"
  11
  12 if [[ ${PV} == "9999" ]] ; then
  13         EGIT_REPO_URI="https://github.com/SimonKagstrom/emilpro"
  14         inherit git-r3
  15         KEYWORDS=""
  16         SRC_URI="mirror://gnu/binutils/binutils-2.23.2.tar.bz2"
  17 else
  18         SRC_URI="http://www.emilpro.com/${P}.tar.gz
  19                 !system-binutils? ( mirror://gnu/binutils/binutils-2.23.2.tar.bz2 )"
  20         KEYWORDS="~amd64 ~x86"
  21 fi
  22
  23 LICENSE="GPL-2"
  24 SLOT="0"
  25 IUSE="+system-binutils"
  26
  27 DEPEND="|| ( dev-libs/elfutils dev-libs/libelf )
  28         dev-cpp/gtkmm:3.0
  29         dev-cpp/gtksourceviewmm:3.0
  30         dev-cpp/libxmlpp:2.6
  31         dev-cpp/glibmm
  32         dev-cpp/pangomm
  33         dev-cpp/cairomm
  34         dev-libs/libsigc++:2
  35         dev-libs/glib:2
  36         system-binutils? ( >=sys-devel/binutils-2.25.1-r1:*[multitarget] )
  37         net-misc/curl"
  38 RDEPEND="${DEPEND}"
  39
  40 src_prepare() {
  41         epatch "${FILESDIR}"/respect-cflags.patch
  42         if use system-binutils; then
  43                 epatch "${FILESDIR}"/use-gentoo-binutils.patch
  44         else
  45                 sed -i "s#wget -O binutils.tar.bz2 https://ftp.gnu.org/gnu/binutils/binutils-2.23.2.tar.bz2#cp \"${DISTDIR}/binutils-2.23.2.tar.bz2\" ./binutils.tar.bz2#" cmake/BuildBinutils.cmake
  46         fi
  47         epatch "${FILESDIR}"/or1k.patch
  48         epatch "${FILESDIR}"/or1k-2.patch
  49         cmake-utils_src_prepare
  50 }
  51
  52 src_compile() {
  53         if use system-binutils; then
  54                 cmake-utils_src_compile
  55         else
  56                 #bundled binutils is broken, always builds with one thread
  57                 #but somehow it still fails if I don't do this
  58                 cd "${BUILD_DIR}"
  59                 emake -j1
  60         fi
  61 }
  62
  63 src_install() {
  64         dobin "${BUILD_DIR}"/emilpro
  65 }