dev-util/d-feet/d-feet-0.3.10.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GCONF_DEBUG="no"
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit gnome2 python-single-r1 virtualx
   9
  10 DESCRIPTION="D-Feet is a powerful D-Bus debugger"
  11 HOMEPAGE="https://wiki.gnome.org/Apps/DFeet"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="amd64 x86"
  16 IUSE="test"
  17 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  18
  19 RDEPEND="
  20         ${PYTHON_DEPS}
  21         >=dev-libs/glib-2.34:2
  22         >=dev-libs/gobject-introspection-0.9.6
  23         >=dev-python/pygobject-3.3.91:3[${PYTHON_USEDEP}]
  24         >=sys-apps/dbus-1
  25         >=x11-libs/gtk+-3.9.4:3[introspection]
  26         x11-libs/libwnck:3[introspection]
  27 "
  28 DEPEND="
  29         ${PYTHON_DEPS}
  30         app-text/yelp-tools
  31         >=dev-util/intltool-0.40.0
  32 "
  33
  34 src_prepare() {
  35         python_fix_shebang .
  36
  37         # Do not run update-desktop-database (sandbox violation)
  38         sed -e '/^UPDATE_DESKTOP/s:=.*:=true:' \
  39                 -i data/Makefile.am data/Makefile.in || die
  40
  41         # disable pep8 - checking python whitespace style is not useful for us
  42         sed -e 's/pep8 /# pep8 /' \
  43                 -i src/tests/Makefile.am src/tests/Makefile.in || die
  44
  45         gnome2_src_prepare
  46 }
  47
  48 src_configure() {
  49         # disable pep8 - checking python code style is not useful downstream
  50         # (especially when that style check fails!)
  51         gnome2_src_configure \
  52                 $(use_enable test tests) \
  53                 PEP8=$(type -P true)
  54 }
  55
  56 src_test() {
  57         Xemake check
  58 }