dev-util/cucumber/cucumber-3.1.0.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 USE_RUBY="ruby22 ruby23 ruby24"
   6
   7 # Documentation task depends on sdoc which we currently don't have.
   8 RUBY_FAKEGEM_TASK_DOC=""
   9 RUBY_FAKEGEM_TASK_TEST="none"
  10 RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
  11
  12 RUBY_FAKEGEM_GEMSPEC="cucumber.gemspec"
  13
  14 inherit ruby-fakegem
  15
  16 DESCRIPTION="Executable feature scenarios"
  17 HOMEPAGE="https://github.com/aslakhellesoy/cucumber/wikis"
  18 SRC_URI="https://github.com/cucumber/cucumber-ruby/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  19 RUBY_S="cucumber-ruby-${PV}"
  20 LICENSE="Ruby"
  21
  22 KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~x86"
  23 SLOT="0"
  24 IUSE="examples test"
  25
  26 ruby_add_bdepend "
  27         test? (
  28                 dev-ruby/rspec:3
  29                 >=dev-ruby/nokogiri-1.5.2
  30                 >=dev-ruby/syntax-1.0.0
  31                 >=dev-util/aruba-0.6.1 =dev-util/aruba-0.6*
  32                 >=dev-ruby/json-1.7
  33                 >=dev-util/cucumber-3
  34                 >=dev-ruby/mime-types-2.99:2
  35         )"
  36
  37 ruby_add_rdepend "
  38         >=dev-ruby/builder-2.1.2:*
  39         dev-util/cucumber-core:3.1
  40         dev-util/cucumber-expressions:5.0
  41         >=dev-util/cucumber-wire-0.0.1:0
  42         >=dev-ruby/diff-lcs-1.1.3
  43         dev-ruby/gherkin:5
  44         >=dev-ruby/multi_json-1.7.5
  45         >=dev-ruby/multi_test-0.1.2
  46 "
  47
  48 all_ruby_prepare() {
  49         # Remove development dependencies from the gemspec that we don't
  50         # need or can't satisfy.
  51         sed -i -e '/\(coveralls\|spork\|simplecov\|bcat\|kramdown\|yard\|capybara\|octokit\|rack-test\|ramaze\|rubocop\|sinatra\|webrat\|mime-types\|rubyzip\)/d' ${RUBY_FAKEGEM_GEMSPEC} || die
  52
  53         # Avoid dependency on unpackaged cucumber-pro
  54         sed -i -e '/cucumber-pro/ s:^:#:' Gemfile || die
  55
  56         # Avoid harmless failing spec
  57         sed -i -e '/converts the snapshot path to a relative path/,/end/ s:^:#:' \
  58                 spec/cucumber/formatter/html_spec.rb || die
  59
  60         # Avoid failing features on new delegate and forwardable behavior in ruby
  61         rm -f features/docs/defining_steps/ambiguous_steps.feature features/docs/defining_steps/nested_steps.feature || die
  62
  63         # Avoid dependency on git
  64         sed -i -e '/executables/ s/=.*/= ["cucumber"]/' \
  65                 -e '/git ls-files/d' cucumber.gemspec || die
  66
  67         sed -i -e '/pry/ s:^:#:' cucumber.gemspec spec/spec_helper.rb || die
  68
  69         rm -f Gemfile.lock || die
  70 }
  71
  72 each_ruby_prepare() {
  73         # Use the right interpreter
  74         sed -i -e 's:ruby:'${RUBY}':' features/lib/step_definitions/ruby_steps.rb || die
  75 }
  76
  77 each_ruby_test() {
  78         RSPEC_VERSION=3 ruby-ng_rspec
  79         CUCUMBER_USE_RELEASED_CORE=true PATH="${S}"/bin:${PATH} RUBYLIB="${S}"/lib ${RUBY} -Ilib bin/cucumber features || die "Features failed"
  80 }
  81
  82 all_ruby_install() {
  83         all_fakegem_install
  84
  85         if use examples; then
  86                 cp -pPR examples "${D}/usr/share/doc/${PF}" || die "Failed installing example files."
  87         fi
  88 }