dev-util/cppunit/cppunit-1.13.1.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=4
   6
   7 EGIT_REPO_URI="git://anongit.freedesktop.org/libreoffice/cppunit"
   8 [[ ${PV} = 9999 ]] && inherit git-2 autotools
   9 inherit eutils flag-o-matic
  10
  11 DESCRIPTION="C++ port of the famous JUnit framework for unit testing"
  12 HOMEPAGE="http://www.freedesktop.org/wiki/Software/cppunit"
  13 [[ ${PV} = 9999 ]] || SRC_URI="http://dev-www.libreoffice.org/src/${P}.tar.gz"
  14
  15 LICENSE="LGPL-2.1"
  16 SLOT="0"
  17 # Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
  18 [[ ${PV} = 9999 ]] || \
  19 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  20 IUSE="doc examples static-libs"
  21
  22 RDEPEND=""
  23 DEPEND="${RDEPEND}
  24         doc? (
  25                 app-doc/doxygen[dot]
  26                 media-gfx/graphviz
  27         )"
  28
  29 DOCS=( AUTHORS BUGS NEWS README THANKS TODO doc/FAQ )
  30 [[ ${PV} = 9999 ]] || DOCS+=( ChangeLog )
  31
  32 src_prepare() {
  33         [[ ${PV} = 9999 ]] && eautoreconf
  34 }
  35
  36 src_configure() {
  37         # Anything else than -O0 breaks on alpha
  38         use alpha && replace-flags "-O?" -O0
  39
  40         econf \
  41                 $(use_enable static-libs static) \
  42                 $(use_enable doc doxygen) \
  43                 $(use_enable doc dot) \
  44                 --docdir="${EPREFIX}"/usr/share/doc/${PF} \
  45                 --htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
  46                 --disable-silent-rules
  47 }
  48
  49 src_install() {
  50         default
  51
  52         prune_libtool_files --all
  53
  54         if use examples ; then
  55                 find examples -iname "*.o" -delete
  56                 insinto /usr/share/${PN}
  57                 doins -r examples
  58         fi
  59 }