dev-util/cppunit/cppunit-1.13.1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=4
   5
   6 EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/cppunit.git"
   7 [[ ${PV} = 9999 ]] && inherit git-2 autotools
   8 inherit eutils flag-o-matic
   9
  10 DESCRIPTION="C++ port of the famous JUnit framework for unit testing"
  11 HOMEPAGE="https://www.freedesktop.org/wiki/Software/cppunit"
  12 [[ ${PV} = 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/${P}.tar.gz"
  13
  14 LICENSE="LGPL-2.1"
  15 SLOT="0"
  16 # Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
  17 [[ ${PV} = 9999 ]] || \
  18 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  19 IUSE="doc examples static-libs"
  20
  21 RDEPEND=""
  22 DEPEND="${RDEPEND}
  23         doc? (
  24                 app-doc/doxygen[dot]
  25                 media-gfx/graphviz
  26         )"
  27
  28 DOCS=( AUTHORS BUGS NEWS README THANKS TODO doc/FAQ )
  29 [[ ${PV} = 9999 ]] || DOCS+=( ChangeLog )
  30
  31 src_prepare() {
  32         [[ ${PV} = 9999 ]] && eautoreconf
  33 }
  34
  35 src_configure() {
  36         # Anything else than -O0 breaks on alpha
  37         use alpha && replace-flags "-O?" -O0
  38
  39         econf \
  40                 $(use_enable static-libs static) \
  41                 $(use_enable doc doxygen) \
  42                 $(use_enable doc dot) \
  43                 --docdir="${EPREFIX}"/usr/share/doc/${PF} \
  44                 --htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
  45                 --disable-silent-rules
  46 }
  47
  48 src_install() {
  49         default
  50
  51         prune_libtool_files --all
  52
  53         if use examples ; then
  54                 find examples -iname "*.o" -delete
  55                 insinto /usr/share/${PN}
  56                 doins -r examples
  57         fi
  58 }