dev-util/conan/conan-1.21.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7 PYTHON_REQ_USE="sqlite"
   8 DISTUTILS_USE_SETUPTOOLS=rdepend
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Distributed C/C++ package manager"
  12 HOMEPAGE="https://conan.io/"
  13 SRC_URI="https://github.com/conan-io/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="MIT"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  18 IUSE="test"
  19
  20 RESTRICT="!test? ( test )"
  21
  22 # overly strict requirements?
  23 # https://github.com/conan-io/conan/blob/develop/conans/requirements.txt
  24 # https://github.com/conan-io/conan/blob/develop/conans/requirements_server.txt
  25 RDEPEND="
  26         >=dev-python/bottle-0.12.8[${PYTHON_USEDEP}]
  27         >=dev-python/colorama-0.3.3[${PYTHON_USEDEP}]
  28         >=dev-python/deprecation-2.0[${PYTHON_USEDEP}]
  29         >=dev-python/distro-1.0.2[${PYTHON_USEDEP}]
  30         >=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
  31         >=dev-python/future-0.16.0[${PYTHON_USEDEP}]
  32         >=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
  33         >=dev-python/node-semver-0.6.1[${PYTHON_USEDEP}]
  34         >=dev-python/patch-ng-1.17.2[${PYTHON_USEDEP}]
  35         >=dev-python/pluginbase-0.5[${PYTHON_USEDEP}]
  36         >=dev-python/pygments-2.0[${PYTHON_USEDEP}]
  37         >=dev-python/pyjwt-1.4[${PYTHON_USEDEP}]
  38         >=dev-python/python-dateutil-2.7.0[${PYTHON_USEDEP}]
  39         >=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
  40         >=dev-python/requests-2.8.1[${PYTHON_USEDEP}]
  41         >=dev-python/six-1.10[${PYTHON_USEDEP}]
  42         >=dev-python/tqdm-4.28.1[${PYTHON_USEDEP}]
  43 "
  44 BDEPEND="
  45         test? (
  46                 dev-lang/go
  47                 dev-vcs/git
  48                 dev-vcs/subversion
  49                 >=dev-python/mock-1.3.0[${PYTHON_USEDEP}]
  50                 >=dev-python/nose-1.3.7[${PYTHON_USEDEP}]
  51                 >=dev-python/parameterized-0.6.3[${PYTHON_USEDEP}]
  52                 >=dev-python/webtest-2.0.18[${PYTHON_USEDEP}]
  53                 dev-util/cmake
  54         )
  55 "
  56
  57 src_prepare() {
  58         default
  59         # Fix strict dependencies
  60         sed -i \
  61                 -e "s:patch==1.16:patch>=1.16:g" \
  62                 -e "s:node-semver==0.6.1:node-semver>=0.6.1:g" \
  63                 -e "s:future==0.16.0:future>=0.16.0:g" \
  64                 conans/requirements.txt || die
  65 }
  66
  67 python_test() {
  68         nosetests -v conans.test \
  69                 -e test_ftp.* -e modify_values_test.* -e test_pkg_config_path.* \
  70                 -e rpath_optin_test -e test_variables -e system_package_tool_installed_test \
  71                 -e virtualbuildenv_test -e scm_test -e test_git_shallow -e tools_test \
  72                 -e test_environment_nested -e devflow_test -e shared_chain_test \
  73                 -e virtualenv_test \
  74                 -A "not rest_api and not local_bottle" || die
  75 }