dev-util/cmake/cmake-3.10.3.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 CMAKE_MAKEFILE_GENERATOR="emake"
   7 CMAKE_REMOVE_MODULES="no"
   8 inherit bash-completion-r1 elisp-common eutils flag-o-matic gnome2-utils toolchain-funcs versionator virtualx xdg-utils cmake-utils
   9
  10 MY_P="${P/_/-}"
  11
  12 DESCRIPTION="Cross platform Make"
  13 HOMEPAGE="https://cmake.org/"
  14 SRC_URI="https://cmake.org/files/v$(get_version_component_range 1-2)/${MY_P}.tar.gz"
  15
  16 LICENSE="CMake"
  17 SLOT="0"
  18 [[ "${PV}" = *_rc* ]] || \
  19 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  20 IUSE="doc emacs system-jsoncpp ncurses qt5"
  21
  22 RDEPEND="
  23         app-crypt/rhash
  24         >=app-arch/libarchive-3.0.0:=
  25         >=dev-libs/expat-2.0.1
  26         >=dev-libs/libuv-1.0.0:=
  27         >=net-misc/curl-7.21.5[ssl]
  28         sys-libs/zlib
  29         virtual/pkgconfig
  30         emacs? ( virtual/emacs )
  31         ncurses? ( sys-libs/ncurses:0= )
  32         qt5? (
  33                 dev-qt/qtcore:5
  34                 dev-qt/qtgui:5
  35                 dev-qt/qtwidgets:5
  36         )
  37         system-jsoncpp? ( >=dev-libs/jsoncpp-0.6.0_rc2:0= )
  38 "
  39 DEPEND="${RDEPEND}
  40         doc? ( dev-python/sphinx )
  41 "
  42
  43 S="${WORKDIR}/${MY_P}"
  44
  45 SITEFILE="50${PN}-gentoo.el"
  46
  47 PATCHES=(
  48         # prefix
  49         "${FILESDIR}"/${PN}-3.4.0_rc1-darwin-bundle.patch
  50         "${FILESDIR}"/${PN}-3.9.0_rc2-prefix-dirs.patch
  51         "${FILESDIR}"/${PN}-3.1.0-darwin-isysroot.patch
  52
  53         # handle gentoo packaging in find modules
  54         "${FILESDIR}"/${PN}-3.9.0_rc2-FindImageMagick.patch
  55         "${FILESDIR}"/${PN}-3.0.0-FindBLAS.patch
  56         "${FILESDIR}"/${PN}-3.8.0_rc2-FindBoost-python.patch
  57         "${FILESDIR}"/${PN}-3.0.2-FindLAPACK.patch
  58         "${FILESDIR}"/${PN}-3.5.2-FindQt4.patch
  59
  60         # respect python eclasses
  61         "${FILESDIR}"/${PN}-2.8.10.2-FindPythonLibs.patch
  62         "${FILESDIR}"/${PN}-3.9.0_rc2-FindPythonInterp.patch
  63
  64         # upstream fixes (can usually be removed with a version bump)
  65 )
  66
  67 cmake_src_bootstrap() {
  68         # Cleanup args to extract only JOBS.
  69         # Because bootstrap does not know anything else.
  70         echo ${MAKEOPTS} | egrep -o '(\-j|\-\-jobs)(=?|[[:space:]]*)[[:digit:]]+' > /dev/null
  71         if [ $? -eq 0 ]; then
  72                 par_arg=$(echo ${MAKEOPTS} | egrep -o '(\-j|\-\-jobs)(=?|[[:space:]]*)[[:digit:]]+' | tail -n1 | egrep -o '[[:digit:]]+')
  73                 par_arg="--parallel=${par_arg}"
  74         else
  75                 par_arg="--parallel=1"
  76         fi
  77
  78         # disable running of cmake in boostrap command
  79         sed -i \
  80                 -e '/"${cmake_bootstrap_dir}\/cmake"/s/^/#DONOTRUN /' \
  81                 bootstrap || die "sed failed"
  82
  83         # execinfo.h on Solaris isn't quite what it is on Darwin
  84         if [[ ${CHOST} == *-solaris* ]] ; then
  85                 sed -i -e 's/execinfo\.h/blablabla.h/' Source/kwsys/CMakeLists.txt || die
  86         fi
  87
  88         tc-export CC CXX LD
  89
  90         # bootstrap script isn't exactly /bin/sh compatible
  91         ${CONFIG_SHELL:-sh} ./bootstrap \
  92                 --prefix="${T}/cmakestrap/" \
  93                 ${par_arg} \
  94                 || die "Bootstrap failed"
  95 }
  96
  97 cmake_src_test() {
  98         # fix OutDir and SelectLibraryConfigurations tests
  99         # these are altered thanks to our eclass
 100         sed -i -e 's:#IGNORE ::g' \
 101                 "${S}"/Tests/{OutDir,CMakeOnly/SelectLibraryConfigurations}/CMakeLists.txt \
 102                 || die
 103
 104         pushd "${BUILD_DIR}" > /dev/null
 105
 106         local ctestargs
 107         [[ -n ${TEST_VERBOSE} ]] && ctestargs="--extra-verbose --output-on-failure"
 108
 109         # Excluded tests:
 110         #    BootstrapTest: we actualy bootstrap it every time so why test it.
 111         #    BundleUtilities: bundle creation broken
 112         #    CTest.updatecvs: which fails to commit as root
 113         #    Fortran: requires fortran
 114         #    Qt4Deploy, which tries to break sandbox and ignores prefix
 115         #    RunCMake.CPack_RPM: breaks if app-arch/rpm is installed because
 116         #        debugedit binary is not in the expected location
 117         #    TestUpload, which requires network access
 118         "${BUILD_DIR}"/bin/ctest ${ctestargs} \
 119                 -E "(BootstrapTest|BundleUtilities|CTest.UpdateCVS|Fortran|Qt4Deploy|RunCMake.CPack_RPM|TestUpload)" \
 120                 || die "Tests failed"
 121
 122         popd > /dev/null
 123 }
 124
 125 src_prepare() {
 126         cmake-utils_src_prepare
 127
 128         # Add gcc libs to the default link paths
 129         sed -i \
 130                 -e "s|@GENTOO_PORTAGE_GCCLIBDIR@|${EPREFIX}/usr/${CHOST}/lib/|g" \
 131                 -e "s|@GENTOO_PORTAGE_EPREFIX@|${EPREFIX}/|g" \
 132                 Modules/Platform/{UnixPaths,Darwin}.cmake || die "sed failed"
 133         if ! has_version \>=${CATEGORY}/${PN}-3.4.0_rc1 ; then
 134                 CMAKE_BINARY="${S}/Bootstrap.cmk/cmake"
 135                 cmake_src_bootstrap
 136         fi
 137 }
 138
 139 src_configure() {
 140         # Fix linking on Solaris
 141         [[ ${CHOST} == *-solaris* ]] && append-ldflags -lsocket -lnsl
 142
 143         local mycmakeargs=(
 144                 -DCMAKE_USE_SYSTEM_LIBRARIES=ON
 145                 -DCMAKE_USE_SYSTEM_LIBRARY_JSONCPP=$(usex system-jsoncpp)
 146                 -DCMAKE_INSTALL_PREFIX="${EPREFIX}"/usr
 147                 -DCMAKE_DOC_DIR=/share/doc/${PF}
 148                 -DCMAKE_MAN_DIR=/share/man
 149                 -DCMAKE_DATA_DIR=/share/${PN}
 150                 -DSPHINX_MAN=$(usex doc)
 151                 -DSPHINX_HTML=$(usex doc)
 152                 -DBUILD_CursesDialog="$(usex ncurses)"
 153         )
 154
 155         if use qt5 ; then
 156                 mycmakeargs+=(
 157                         -DBUILD_QtDialog=ON
 158                         $(cmake-utils_use_find_package qt5 Qt5Widgets)
 159                 )
 160         fi
 161
 162         cmake-utils_src_configure
 163 }
 164
 165 src_compile() {
 166         cmake-utils_src_compile
 167         use emacs && elisp-compile Auxiliary/cmake-mode.el
 168 }
 169
 170 src_test() {
 171         virtx cmake_src_test
 172 }
 173
 174 src_install() {
 175         cmake-utils_src_install
 176
 177         if use emacs; then
 178                 elisp-install ${PN} Auxiliary/cmake-mode.el Auxiliary/cmake-mode.elc
 179                 elisp-site-file-install "${FILESDIR}/${SITEFILE}"
 180         fi
 181
 182         insinto /usr/share/vim/vimfiles/syntax
 183         doins Auxiliary/vim/syntax/cmake.vim
 184
 185         insinto /usr/share/vim/vimfiles/indent
 186         doins Auxiliary/vim/indent/cmake.vim
 187
 188         insinto /usr/share/vim/vimfiles/ftdetect
 189         doins "${FILESDIR}/${PN}.vim"
 190
 191         dobashcomp Auxiliary/bash-completion/{${PN},ctest,cpack}
 192
 193         rm -r "${ED}"/usr/share/cmake/{completions,editors} || die
 194 }
 195
 196 pkg_postinst() {
 197         use emacs && elisp-site-regen
 198         if use qt5; then
 199                 gnome2_icon_cache_update
 200                 xdg_desktop_database_update
 201                 xdg_mimeinfo_database_update
 202         fi
 203 }
 204
 205 pkg_postrm() {
 206         use emacs && elisp-site-regen
 207         if use qt5; then
 208                 gnome2_icon_cache_update
 209                 xdg_desktop_database_update
 210                 xdg_mimeinfo_database_update
 211         fi
 212 }