dev-util/catalyst/catalyst-3.0.8.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 if [[ ${PV} == *9999* ]]; then
   7         SRC_ECLASS="git-r3"
   8         EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/catalyst.git"
   9         EGIT_BRANCH="master"
  10 else
  11         SRC_URI="https://gitweb.gentoo.org/proj/catalyst.git/snapshot/${P}.tar.bz2"
  12         KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~riscv s390 sh sparc x86"
  13 fi
  14
  15 PYTHON_COMPAT=( python3_{6,7,8} )
  16
  17 inherit distutils-r1 ${SRC_ECLASS}
  18
  19 DESCRIPTION="Release metatool used for creating releases based on Gentoo Linux"
  20 HOMEPAGE="https://wiki.gentoo.org/wiki/Catalyst"
  21
  22 LICENSE="GPL-2"
  23 SLOT="0"
  24 IUSE="ccache doc +iso kernel_linux system-bootloader"
  25
  26 DEPEND="
  27         app-text/asciidoc
  28         >=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
  29 "
  30 RDEPEND="
  31         >=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
  32         >=dev-python/pydecomp-0.3[${PYTHON_USEDEP}]
  33         app-arch/lbzip2
  34         app-crypt/shash
  35         sys-fs/dosfstools
  36         !kernel_FreeBSD? ( || ( app-arch/tar[xattr] app-arch/libarchive[xattr] ) )
  37         kernel_FreeBSD? ( app-arch/libarchive[xattr] )
  38         amd64? ( >=sys-boot/syslinux-3.72 )
  39         x86? ( >=sys-boot/syslinux-3.72 )
  40         ccache? ( dev-util/ccache )
  41         iso? ( virtual/cdrtools )
  42         kernel_linux? ( app-misc/zisofs-tools >=sys-fs/squashfs-tools-2.1 )
  43 "
  44 PDEPEND="system-bootloader? ( >=sys-apps/memtest86+-5.01-r4
  45                                 sys-boot/grub:2
  46                                 amd64? ( sys-boot/grub[grub_platforms_efi-32,grub_platforms_efi-64] )
  47                                 x86? ( sys-boot/grub[grub_platforms_efi-32] )
  48                                 sys-boot/syslinux
  49                                 sys-boot/shim )"
  50
  51 python_prepare_all() {
  52         python_setup
  53         echo VERSION="${PV}" "${PYTHON}" setup.py set_version
  54         VERSION="${PV}" "${PYTHON}" setup.py set_version || die
  55         distutils-r1_python_prepare_all
  56 }
  57
  58 python_compile_all() {
  59         # build the man pages and docs
  60         emake
  61 }
  62
  63 python_install_all() {
  64         distutils-r1_python_install_all
  65         if use doc; then
  66                 dodoc files/HOWTO.html files/docbook-xsl.css
  67         fi
  68 }