dev-util/boost-build/boost-build-1.60.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="6"
   6
   7 RESTRICT="test"
   8
   9 PYTHON_COMPAT=( python2_7 )
  10 inherit eutils flag-o-matic python-single-r1 toolchain-funcs versionator
  11
  12 MY_PV="$(replace_all_version_separators _)"
  13
  14 DESCRIPTION="A system for large project software construction, simple to use and powerful"
  15 HOMEPAGE="http://www.boost.org/doc/tools/build/index.html"
  16 SRC_URI="mirror://sourceforge/boost/boost_${MY_PV}.tar.bz2"
  17
  18 LICENSE="Boost-1.0"
  19 SLOT="0"
  20 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  21 IUSE="examples python test"
  22
  23 RDEPEND="python? ( ${PYTHON_DEPS} )
  24         !<dev-libs/boost-1.34.0
  25         !<=dev-util/boost-build-1.35.0-r1"
  26 DEPEND="${RDEPEND}
  27         test? ( sys-apps/diffutils
  28                 ${PYTHON_DEPS} )"
  29
  30 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
  31         test? ( ${PYTHON_REQUIRED_USE} )"
  32
  33 S="${WORKDIR}/boost_${MY_PV}/tools/build/src"
  34
  35 pkg_setup() {
  36         if use python || use test; then
  37                 python-single-r1_pkg_setup
  38         fi
  39 }
  40
  41 src_unpack() {
  42         tar xjpf "${DISTDIR}/${A}" boost_${MY_PV}/tools/build || die "unpacking tar failed"
  43 }
  44
  45 src_prepare() {
  46         epatch \
  47                 "${FILESDIR}/${PN}-1.48.0-disable_python_rpath.patch" \
  48                 "${FILESDIR}/${PN}-1.50.0-respect-c_ld-flags.patch" \
  49                 "${FILESDIR}/${PN}-1.49.0-darwin-gentoo-toolchain.patch" \
  50                 "${FILESDIR}/${PN}-1.52.0-darwin-no-python-framework.patch" \
  51                 "${FILESDIR}/${PN}-1.54.0-support_dots_in_python-buildid.patch" \
  52                 "${FILESDIR}/${PN}-1.55.0-ppc-aix.patch"
  53
  54         pushd ../ &>/dev/null || die
  55         epatch "${FILESDIR}/${PN}-1.54.0-fix-test.patch"
  56         popd &>/dev/null || die
  57
  58         # Remove stripping option
  59         # Fix python components build on multilib systems, bug #496446
  60         cd "${S}/engine" || die
  61         sed -i \
  62                 -e 's|-s\b||' \
  63                 -e "/libpython/s/lib ]/$(get_libdir) ]/" \
  64                 build.jam || die "sed failed"
  65
  66         # Force regeneration
  67         rm jambase.c || die
  68
  69         # This patch allows us to fully control optimization
  70         # and stripping flags when bjam is used as build-system
  71         # We simply extend the optimization and debug-symbols feature
  72         # with empty dummies called 'none'
  73         cd "${S}" || die
  74         sed -i \
  75                 -e 's/\(off speed space\)/\1 none/' \
  76                 -e 's/\(debug-symbols      : on off\)/\1 none/' \
  77                 tools/builtin.jam || die "sed failed"
  78
  79         eapply_user
  80 }
  81
  82 src_configure() {
  83         if use python; then
  84                 # replace versions by user-selected one (TODO: fix this when slot-op
  85                 # deps are available to always match the best version available)
  86                 sed -i \
  87                         -e "s|2.7 2.6 2.5 2.4 2.3 2.2|${EPYTHON#python}|" \
  88                         engine/build.jam || die "sed failed"
  89         fi
  90 }
  91
  92 src_compile() {
  93         cd engine || die
  94
  95         local toolset
  96
  97         if [[ ${CHOST} == *-darwin* ]]; then
  98                 toolset=darwin
  99         else
 100                 # Using boost's generic toolset here, which respects CC and CFLAGS
 101                 toolset=cc
 102         fi
 103
 104         CC=$(tc-getCC) ./build.sh ${toolset} -d+2 $(use_with python python "${EROOT}"/usr) || die "building bjam failed"
 105 }
 106
 107 src_install() {
 108         dobin engine/bin.*/{bjam,b2}
 109
 110         insinto /usr/share/boost-build
 111         doins -r "${FILESDIR}/site-config.jam" \
 112                 ../boost-build.jam bootstrap.jam build-system.jam ../example/user-config.jam *.py \
 113                 build kernel options tools util
 114
 115         rm "${ED}/usr/share/boost-build/build/project.ann.py" || die "removing faulty python file failed"
 116         if ! use python; then
 117                 find "${ED}/usr/share/boost-build" -iname "*.py" -delete || die "removing experimental python files failed"
 118         fi
 119
 120         dodoc ../notes/{changes,hacking,release_procedure,build_dir_option,relative_source_paths}.txt
 121
 122         if use examples; then
 123                 dodoc -r ../example
 124                 docompress -x "/usr/share/doc/${PF}/example"
 125         fi
 126 }
 127
 128 src_test() {
 129         cd ../test || die
 130
 131         export TMP="${T}"
 132
 133         DO_DIFF="${PREFIX}/usr/bin/diff" ${PYTHON} test_all.py
 134
 135         if [[ -s test_results.txt ]]; then
 136                 eerror "At least one test failed: $(<test_results.txt)"
 137                 die "tests failed"
 138         fi
 139 }