dev-util/boost-build/boost-build-1.55.0.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 PYTHON_DEPEND="python? 2"
   7
   8 RESTRICT="test"
   9
  10 inherit eutils flag-o-matic multilib python toolchain-funcs versionator
  11
  12 MY_PV=$(replace_all_version_separators _)
  13
  14 DESCRIPTION="A system for large project software construction, simple to use and powerful"
  15 HOMEPAGE="http://www.boost.org/doc/tools/build/index.html"
  16 SRC_URI="mirror://sourceforge/boost/boost_${MY_PV}.tar.bz2"
  17
  18 LICENSE="Boost-1.0"
  19 SLOT=0
  20 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  21 IUSE="examples python test"
  22
  23 REQUIRED_USE="test? ( python )"
  24
  25 RDEPEND="!<dev-libs/boost-1.34.0
  26         !<=dev-util/boost-build-1.35.0-r1"
  27 DEPEND="${RDEPEND}
  28         test? ( sys-apps/diffutils )"
  29
  30 S="${WORKDIR}/boost_${MY_PV}/tools/build/v2"
  31
  32 pkg_setup() {
  33         if use python; then
  34                 python_set_active_version 2
  35                 python_pkg_setup
  36         fi
  37 }
  38
  39 src_unpack() {
  40         tar xjpf "${DISTDIR}/${A}" boost_${MY_PV}/tools/build/v2 || die "unpacking tar failed"
  41 }
  42
  43 src_prepare() {
  44         epatch \
  45                 "${FILESDIR}/${PN}-1.48.0-disable_python_rpath.patch" \
  46                 "${FILESDIR}/${PN}-1.50.0-respect-c_ld-flags.patch" \
  47                 "${FILESDIR}/${PN}-1.49.0-darwin-gentoo-toolchain.patch" \
  48                 "${FILESDIR}/${PN}-1.52.0-darwin-no-python-framework.patch" \
  49                 "${FILESDIR}/${PN}-1.54.0-fix-test.patch" \
  50                 "${FILESDIR}/${PN}-1.54.0-support_dots_in_python-buildid.patch" \
  51                 "${FILESDIR}/${PN}-1.55.0-ppc-aix.patch"
  52
  53         # Remove stripping option
  54         # Fix python components build on multilib systems, bug #496446
  55         cd "${S}/engine"
  56         sed -i \
  57                 -e 's|-s\b||' \
  58                 -e "/libpython/s/lib ]/$(get_libdir) ]/" \
  59                 build.jam || die "sed failed"
  60
  61         # Force regeneration
  62         rm jambase.c || die
  63
  64         # This patch allows us to fully control optimization
  65         # and stripping flags when bjam is used as build-system
  66         # We simply extend the optimization and debug-symbols feature
  67         # with empty dummies called 'none'
  68         cd "${S}"
  69         sed -i \
  70                 -e 's/\(off speed space\)/\1 none/' \
  71                 -e 's/\(debug-symbols      : on off\)/\1 none/' \
  72                 tools/builtin.jam || die "sed failed"
  73 }
  74
  75 src_configure() {
  76         if use python; then
  77                 # replace versions by user-selected one (TODO: fix this when slot-op
  78                 # deps are available to always match the best version available)
  79                 sed -i \
  80                         -e "s|2.7 2.6 2.5 2.4 2.3 2.2|${PYTHON_ABI}|" \
  81                         engine/build.jam || die "sed failed"
  82         fi
  83 }
  84
  85 src_compile() {
  86         cd engine
  87
  88         local toolset
  89
  90         if [[ ${CHOST} == *-darwin* ]]; then
  91                 toolset=darwin
  92         else
  93                 # Using boost's generic toolset here, which respects CC and CFLAGS
  94                 toolset=cc
  95         fi
  96
  97         CC=$(tc-getCC) ./build.sh ${toolset} -d+2 $(use_with python python "${EROOT}"/usr) || die "building bjam failed"
  98 }
  99
 100 src_install() {
 101         dobin engine/bin.*/{bjam,b2}
 102
 103         insinto /usr/share/boost-build
 104         doins -r "${FILESDIR}/site-config.jam" \
 105                 boost-build.jam bootstrap.jam build-system.jam user-config.jam *.py \
 106                 build kernel options tools util
 107
 108         rm "${ED}/usr/share/boost-build/build/project.ann.py" || die "removing faulty python file failed"
 109         if ! use python; then
 110                 find "${ED}/usr/share/boost-build" -iname "*.py" -delete || die "removing experimental python files failed"
 111         fi
 112
 113         dodoc changes.txt hacking.txt release_procedure.txt \
 114                 notes/build_dir_option.txt notes/relative_source_paths.txt
 115
 116         if use examples; then
 117                 insinto /usr/share/doc/${PF}
 118                 doins -r example
 119         fi
 120 }
 121
 122 src_test() {
 123         cd test
 124
 125         export TMP="${T}"
 126
 127         DO_DIFF="${PREFIX}/usr/bin/diff" $(PYTHON -2) test_all.py
 128
 129         if [[ -s test_results.txt ]]; then
 130                 eerror "At least one test failed: $(<test_results.txt)"
 131                 die "tests failed"
 132         fi
 133 }
 134
 135 pkg_postinst() {
 136         use python && python_mod_optimize /usr/share/boost-build
 137 }
 138
 139 pkg_postrm() {
 140         use python && python_mod_cleanup /usr/share/boost-build
 141 }