dev-util/boost-build/boost-build-1.55.0-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6
   7 RESTRICT="test"
   8
   9 PYTHON_COMPAT=( python2_7 )
  10 inherit eutils flag-o-matic multilib python-single-r1 toolchain-funcs versionator
  11
  12 MY_PV=$(replace_all_version_separators _)
  13
  14 DESCRIPTION="A system for large project software construction, simple to use and powerful"
  15 HOMEPAGE="http://www.boost.org/doc/tools/build/index.html"
  16 SRC_URI="mirror://sourceforge/boost/boost_${MY_PV}.tar.bz2"
  17
  18 LICENSE="Boost-1.0"
  19 SLOT=0
  20 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  21 IUSE="examples python test"
  22
  23 RDEPEND="python? ( ${PYTHON_DEPS} )
  24         !<dev-libs/boost-1.34.0
  25         !<=dev-util/boost-build-1.35.0-r1"
  26 DEPEND="${RDEPEND}
  27         test? ( sys-apps/diffutils
  28                 ${PYTHON_DEPS} )"
  29
  30 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
  31         test? ( ${PYTHON_REQUIRED_USE} )"
  32
  33 S="${WORKDIR}/boost_${MY_PV}/tools/build/v2"
  34
  35 pkg_setup() {
  36         if use python || use test; then
  37                 python-single-r1_pkg_setup
  38         fi
  39 }
  40
  41 src_unpack() {
  42         tar xjpf "${DISTDIR}/${A}" boost_${MY_PV}/tools/build/v2 || die "unpacking tar failed"
  43 }
  44
  45 src_prepare() {
  46         epatch \
  47                 "${FILESDIR}/${PN}-1.48.0-disable_python_rpath.patch" \
  48                 "${FILESDIR}/${PN}-1.50.0-respect-c_ld-flags.patch" \
  49                 "${FILESDIR}/${PN}-1.49.0-darwin-gentoo-toolchain.patch" \
  50                 "${FILESDIR}/${PN}-1.52.0-darwin-no-python-framework.patch" \
  51                 "${FILESDIR}/${PN}-1.54.0-fix-test.patch" \
  52                 "${FILESDIR}/${PN}-1.54.0-support_dots_in_python-buildid.patch" \
  53                 "${FILESDIR}/${PN}-1.55.0-ppc-aix.patch"
  54
  55         # Remove stripping option
  56         # Fix python components build on multilib systems, bug #496446
  57         cd "${S}/engine" || die
  58         sed -i \
  59                 -e 's|-s\b||' \
  60                 -e "/libpython/s/lib ]/$(get_libdir) ]/" \
  61                 build.jam || die "sed failed"
  62
  63         # Force regeneration
  64         rm jambase.c || die
  65
  66         # This patch allows us to fully control optimization
  67         # and stripping flags when bjam is used as build-system
  68         # We simply extend the optimization and debug-symbols feature
  69         # with empty dummies called 'none'
  70         cd "${S}" || die
  71         sed -i \
  72                 -e 's/\(off speed space\)/\1 none/' \
  73                 -e 's/\(debug-symbols      : on off\)/\1 none/' \
  74                 tools/builtin.jam || die "sed failed"
  75
  76         epatch_user
  77 }
  78
  79 src_configure() {
  80         if use python; then
  81                 # replace versions by user-selected one (TODO: fix this when slot-op
  82                 # deps are available to always match the best version available)
  83                 sed -i \
  84                         -e "s|2.7 2.6 2.5 2.4 2.3 2.2|${EPYTHON#python}|" \
  85                         engine/build.jam || die "sed failed"
  86         fi
  87 }
  88
  89 src_compile() {
  90         cd engine || die
  91
  92         local toolset
  93
  94         if [[ ${CHOST} == *-darwin* ]]; then
  95                 toolset=darwin
  96         else
  97                 # Using boost's generic toolset here, which respects CC and CFLAGS
  98                 toolset=cc
  99         fi
 100
 101         CC=$(tc-getCC) ./build.sh ${toolset} -d+2 $(use_with python python "${EROOT}"/usr) || die "building bjam failed"
 102 }
 103
 104 src_install() {
 105         dobin engine/bin.*/{bjam,b2}
 106
 107         insinto /usr/share/boost-build
 108         doins -r "${FILESDIR}/site-config.jam" \
 109                 boost-build.jam bootstrap.jam build-system.jam user-config.jam *.py \
 110                 build kernel options tools util
 111
 112         rm "${ED}/usr/share/boost-build/build/project.ann.py" || die "removing faulty python file failed"
 113         if ! use python; then
 114                 find "${ED}/usr/share/boost-build" -iname "*.py" -delete || die "removing experimental python files failed"
 115         fi
 116
 117         dodoc changes.txt hacking.txt release_procedure.txt \
 118                 notes/build_dir_option.txt notes/relative_source_paths.txt
 119
 120         if use examples; then
 121                 dodoc -r example
 122                 docompress -x "/usr/share/doc/${PF}/example"
 123         fi
 124 }
 125
 126 src_test() {
 127         cd test || die
 128
 129         export TMP="${T}"
 130
 131         DO_DIFF="${PREFIX}/usr/bin/diff" ${PYTHON} test_all.py
 132
 133         if [[ -s test_results.txt ]]; then
 134                 eerror "At least one test failed: $(<test_results.txt)"
 135                 die "tests failed"
 136         fi
 137 }