dev-util/aruba/aruba-0.7.4.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 USE_RUBY="ruby19 ruby20 ruby21 ruby22"
   7
   8 RUBY_FAKEGEM_TASK_DOC=""
   9 RUBY_FAKEGEM_RECIPE_TEST="cucumber"
  10 RUBY_FAKEGEM_EXTRADOC="History.md README.md"
  11
  12 RUBY_FAKEGEM_GEMSPEC="aruba.gemspec"
  13
  14 inherit ruby-fakegem
  15
  16 DESCRIPTION="Cucumber steps for driving out command line applications"
  17 HOMEPAGE="https://github.com/cucumber/aruba"
  18 LICENSE="MIT"
  19
  20 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
  21 SLOT="0"
  22 IUSE=""
  23
  24 DEPEND="${DEPEND} test? ( sys-devel/bc )"
  25 RDEPEND="${RDEPEND}"
  26
  27 ruby_add_rdepend "
  28         >=dev-ruby/childprocess-0.3.6
  29         >=dev-ruby/rspec-expectations-2.7:2
  30         >=dev-util/cucumber-1.1.1"
  31
  32 ruby_add_bdepend "test? ( dev-ruby/rspec:3 >=dev-ruby/bcat-0.6.1 )"
  33
  34 all_ruby_prepare() {
  35         # Remove bundler-related code.
  36         sed -i -e '/[Bb]undler/d' Rakefile spec/spec_helper.rb || die
  37         rm Gemfile || die
  38
  39         sed -i -e '/simplecov/I s:^:#:' \
  40                 -e '/Before/,/^end/ s:^:#:' \
  41                 spec/spec_helper.rb features/support/env.rb || die
  42         rm -f features/support/simplecov_setup.rb || die
  43         sed -i -e '1i require "time"' spec/spec_helper.rb || die
  44
  45         # Remove references to git ls-files.
  46         sed -i -e '/git ls-files/d' aruba.gemspec || die
  47 }
  48
  49 each_ruby_test() {
  50         RSPEC_VERSION=3 ruby-ng_rspec
  51         ruby-ng_cucumber
  52 }