dev-util/apitrace/apitrace-4.0.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit cmake-multilib eutils python-single-r1 vcs-snapshot
   9
  10 DESCRIPTION="A tool for tracing, analyzing, and debugging graphics APIs"
  11 HOMEPAGE="https://github.com/apitrace/apitrace"
  12 SRC_URI="https://github.com/${PN}/${PN}/tarball/${PV} -> ${P}.tar.gz"
  13
  14 LICENSE="MIT"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm ~x86"
  17 IUSE="+cli egl qt4"
  18
  19 RDEPEND="${PYTHON_DEPS}
  20         >=app-arch/snappy-1.1.1[${MULTILIB_USEDEP}]
  21         >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
  22         >=media-libs/mesa-9.1.6[egl?,${MULTILIB_USEDEP}]
  23         egl? ( || (
  24                 >=media-libs/mesa-8.0[gles1,gles2]
  25                 <media-libs/mesa-8.0[gles]
  26         ) )
  27         media-libs/libpng:0=
  28         sys-process/procps
  29         x11-libs/libX11
  30         qt4? (
  31                 >=dev-qt/qtcore-4.7:4
  32                 >=dev-qt/qtgui-4.7:4
  33                 >=dev-qt/qtwebkit-4.7:4
  34                 >=dev-libs/qjson-0.5
  35         )"
  36 DEPEND="${RDEPEND}"
  37
  38 PATCHES=(
  39         "${FILESDIR}"/${P}-system-libs.patch
  40         "${FILESDIR}"/${P}-glxtrace-only.patch
  41         "${FILESDIR}"/${P}-glext-texture-storage.patch
  42         "${FILESDIR}"/${P}-glxcopysubbuffermesa.patch
  43         "${FILESDIR}"/${P}-multilib.patch
  44         "${FILESDIR}"/${P}-disable-multiarch.patch
  45         "${FILESDIR}"/${P}-memcpy.patch
  46 )
  47
  48 src_prepare() {
  49         enable_cmake-utils_src_prepare
  50
  51         # The apitrace code grubs around in the internal zlib structures.
  52         # We have to extract this header and clean it up to keep that working.
  53         # Do not be surprised if a zlib upgrade breaks things ...
  54         sed -r \
  55                 -e 's:OF[(]([^)]*)[)]:\1:' \
  56                 thirdparty/zlib/gzguts.h > gzguts.h
  57         rm -rf "${S}"/thirdparty/{getopt,less,libpng,snappy,zlib}
  58 }
  59
  60 src_configure() {
  61         my_configure() {
  62                 mycmakeargs=(
  63                         -DARCH_SUBDIR=
  64                         $(cmake-utils_use_enable egl EGL)
  65                 )
  66                 if multilib_is_native_abi ; then
  67                         mycmakeargs+=(
  68                                 $(cmake-utils_use_enable cli CLI)
  69                                 $(cmake-utils_use_enable qt4 GUI)
  70                         )
  71                 else
  72                         mycmakeargs+=(
  73                                 -DBUILD_LIB_ONLY=ON
  74                                 -DENABLE_CLI=OFF
  75                                 -DENABLE_GUI=OFF
  76                         )
  77                 fi
  78                 cmake-utils_src_configure
  79         }
  80
  81         multilib_parallel_foreach_abi my_configure
  82 }
  83
  84 src_install() {
  85         cmake-multilib_src_install
  86
  87         dosym glxtrace.so /usr/$(get_libdir)/${PN}/wrappers/libGL.so
  88         dosym glxtrace.so /usr/$(get_libdir)/${PN}/wrappers/libGL.so.1
  89         dosym glxtrace.so /usr/$(get_libdir)/${PN}/wrappers/libGL.so.1.2
  90
  91         dodoc {BUGS,DEVELOPMENT,NEWS,README,TODO}.markdown
  92
  93         exeinto /usr/$(get_libdir)/${PN}/scripts
  94         doexe $(find scripts -type f -executable)
  95 }