dev-util/android-ndk/android-ndk-9.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 MY_P="${PN}-r${PV}"
   8
   9 DESCRIPTION="Open Handset Alliance's Android NDK (Native Dev Kit)"
  10 HOMEPAGE="http://developer.android.com/sdk/ndk/"
  11 SRC_URI="x86? ( https://dl.google.com/android/ndk/${MY_P}-linux-x86.tar.bz2
  12         legacy-toolchains? ( https://dl.google.com/android/ndk/${MY_P}-linux-x86-legacy-toolchains.tar.bz2 ) )
  13         amd64? ( https://dl.google.com/android/ndk/${MY_P}-linux-x86_64.tar.bz2
  14         legacy-toolchains? ( https://dl.google.com/android/ndk/${MY_P}-linux-x86_64-legacy-toolchains.tar.bz2 ) )"
  15
  16 LICENSE="android"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~x86"
  19 IUSE="legacy-toolchains"
  20 RESTRICT="mirror strip installsources test"
  21
  22 DEPEND=""
  23 RDEPEND=">=dev-util/android-sdk-update-manager-10
  24         >=sys-devel/make-3.81"
  25
  26 S="${WORKDIR}/${MY_P}"
  27
  28 ANDROID_NDK_DIR="opt/${PN}"
  29
  30 QA_PREBUILT="*"
  31 PYTHON_UPDATER_IGNORE="1"
  32
  33 src_configure() {
  34         :
  35 }
  36
  37 src_compile() {
  38         :
  39 }
  40
  41 src_install() {
  42         dodir "/${ANDROID_NDK_DIR}"
  43         cp -pPR * "${ED}/${ANDROID_NDK_DIR}" || die
  44
  45         fowners -R root:android "/${ANDROID_NDK_DIR}"
  46         fperms 0775 "/${ANDROID_NDK_DIR}/"{,build,docs,platforms,samples}
  47         fperms 0775 "/${ANDROID_NDK_DIR}/"{sources,tests,toolchains}
  48
  49         dodir "/${ANDROID_NDK_DIR}/out"
  50         fowners root:android "/${ANDROID_NDK_DIR}/out"
  51         fperms 3775 "/${ANDROID_NDK_DIR}/out"
  52
  53         ANDROID_PREFIX="${EPREFIX}/${ANDROID_NDK_DIR}"
  54         ANDROID_PATH="${EPREFIX}/${ANDROID_NDK_DIR}"
  55
  56         for i in toolchains/*/prebuilt/linux-*/bin
  57         do
  58                 ANDROID_PATH="${ANDROID_PATH}:${ANDROID_PREFIX}/${i}"
  59         done
  60
  61         printf '%s' \
  62                 "PATH=\"${ANDROID_PATH}\"" \
  63                 $'\n' \
  64                 > "${T}/80${PN}"  || die
  65
  66         doenvd "${T}/80${PN}"
  67
  68         echo "SEARCH_DIRS_MASK=\"${EPREFIX}/${ANDROID_NDK_DIR}\"" \
  69                 > "${T}/80${PN}" || die
  70         insinto "/etc/revdep-rebuild"
  71         doins "${T}/80${PN}"
  72 }