dev-util/android-ndk/android-ndk-10b.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 DESCRIPTION="Open Handset Alliance's Android NDK (Native Dev Kit)"
   7 HOMEPAGE="https://developer.android.com/ndk/"
   8 SRC_URI="x86? ( target-32? ( https://dl.google.com/android/ndk/${PN}32-r${PV}-linux-x86.tar.bz2 )
   9                 target-64? ( https://dl.google.com/android/ndk/${PN}64-r${PV}-linux-x86.tar.bz2 ) )
  10         amd64? ( target-32? ( https://dl.google.com/android/ndk/${PN}32-r${PV}-linux-x86_64.tar.bz2 )
  11                 target-64? (  https://dl.google.com/android/ndk/${PN}64-r${PV}-linux-x86_64.tar.bz2 ) )"
  12
  13 LICENSE="android"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="+target-32 target-64"
  17 RESTRICT="mirror strip installsources test"
  18
  19 DEPEND=""
  20 RDEPEND=">=dev-util/android-sdk-update-manager-10
  21         >=sys-devel/make-3.81"
  22
  23 S="${WORKDIR}/${PN}-r${PV}"
  24
  25 ANDROID_NDK_DIR="opt/${PN}"
  26
  27 QA_PREBUILT="*"
  28 PYTHON_UPDATER_IGNORE="1"
  29
  30 src_configure() {
  31         :
  32 }
  33
  34 src_compile() {
  35         :
  36 }
  37
  38 src_install() {
  39         dodir "/${ANDROID_NDK_DIR}"
  40         cp -pPR * "${ED}/${ANDROID_NDK_DIR}" || die
  41
  42         fowners -R root:android "/${ANDROID_NDK_DIR}"
  43         fperms 0775 "/${ANDROID_NDK_DIR}/"{,build,docs,platforms,samples}
  44         fperms 0775 "/${ANDROID_NDK_DIR}/"{sources,tests,toolchains}
  45
  46         dodir "/${ANDROID_NDK_DIR}/out"
  47         fowners root:android "/${ANDROID_NDK_DIR}/out"
  48         fperms 3775 "/${ANDROID_NDK_DIR}/out"
  49
  50         ANDROID_PREFIX="${EPREFIX}/${ANDROID_NDK_DIR}"
  51         ANDROID_PATH="${EPREFIX}/${ANDROID_NDK_DIR}"
  52
  53         for i in toolchains/*/prebuilt/linux-*/bin
  54         do
  55                 ANDROID_PATH="${ANDROID_PATH}:${ANDROID_PREFIX}/${i}"
  56         done
  57
  58         printf '%s' \
  59                 "PATH=\"${ANDROID_PATH}\"" \
  60                 $'\n' \
  61                 > "${T}/80${PN}"  || die
  62
  63         doenvd "${T}/80${PN}"
  64
  65         echo "SEARCH_DIRS_MASK=\"${EPREFIX}/${ANDROID_NDK_DIR}\"" \
  66                 > "${T}/80${PN}" || die
  67         insinto "/etc/revdep-rebuild"
  68         doins "${T}/80${PN}"
  69 }