dev-tex/pgf/pgf-3.1.5b.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit latex-package
   7
   8 DESCRIPTION="The TeX Portable Graphic Format"
   9 HOMEPAGE="https://github.com/pgf-tikz/pgf"
  10 SRC_URI=" https://github.com/pgf-tikz/pgf/archive/${PV}.tar.gz -> ${P}.tar.gz
  11         https://dev.gentoo.org/~zlogene/distfiles/${CATEGORY}/${PN}/${P}-revisioned.xz
  12         doc? ( https://github.com/pgf-tikz/pgf/releases/download/${PV}/pgfmanual.pdf -> ${P}-pgfmanual.pdf )"
  13
  14 LICENSE="GPL-2 LPPL-1.3c FDL-1.2"
  15 SLOT="0"
  16 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="doc source"
  18
  19 RDEPEND="dev-texlive/texlive-latexrecommended"
  20
  21 src_install() {
  22         insinto "${TEXMF}"
  23         doins -r tex
  24         insinto "${TEXMF}"/tex/generic/${PN}
  25         newins "${WORKDIR}"/${P}-revisioned pgf.revision.tex
  26
  27         if use source ; then
  28                 doins -r source
  29         fi
  30
  31         cd "${S}/doc/generic/pgf" || die
  32         dodoc AUTHORS ChangeLog README
  33         if use doc; then
  34                 docinto texdoc
  35                 # pgfmanual is now split from the main tar archive
  36                 newdoc "${DISTDIR}/${P}-pgfmanual.pdf" pgfmanual.pdf
  37                 doins -r images macros text-en version-*
  38                 rm version-for-dvisvgm/en/color.cfg || die # bug 700056
  39
  40                 dosym "../../../doc/${PF}/texdoc" "${TEXMF}/doc/latex/${PN}"
  41                 docompress -x "/usr/share/doc/${P}/texdoc/"
  42         fi
  43 }