dev-tex/cjk-latex/cjk-latex-4.8.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit latex-package elisp-common toolchain-funcs flag-o-matic
   7
   8 MY_P="${P/-latex/}"
   9
  10 DESCRIPTION="LaTeX package to use CJK (Chinese/Japanese/Korean) scripts in various encodings"
  11 HOMEPAGE="https://cjk.ffii.org/"
  12 # fonts are taken from ftp://ftp.ctan.org/tex-archive/fonts/CJK.zip
  13 SRC_URI="ftp://ftp.ffii.org/pub/cjk/${MY_P}.tar.gz
  14         mirror://gentoo/${MY_P}-fonts.zip
  15         doc? ( ftp://ftp.ffii.org/pub/cjk/${MY_P}-doc.tar.gz )"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
  20 IUSE="doc emacs"
  21
  22 RDEPEND="virtual/latex-base
  23         dev-libs/kpathsea
  24         emacs? ( >=app-editors/emacs-23.1:* )"
  25
  26 DEPEND="${RDEPEND}"
  27
  28 BDEPEND="app-arch/unzip
  29         virtual/pkgconfig"
  30
  31 S="${WORKDIR}/${MY_P}"
  32
  33 src_prepare() {
  34         default
  35         for i in "${WORKDIR}"/CJK/*.tar.gz; do
  36                 tar -xzf ${i} || die "failed to unpack $i"
  37         done
  38         find texmf/fonts/hbf -type f -exec cp {} "${T}" \; || die
  39         sed -i -e "/^pk_files/s/no/yes/" \
  40                 -e "/^dpi_x/s/300/500/" \
  41                 texmf/hbf2gf/*.cfg || die
  42 }
  43
  44 src_configure() {
  45         has_version '>=dev-libs/kpathsea-6.2.1' && append-cppflags "$($(tc-getPKG_CONFIG) --cflags kpathsea)"
  46         cd utils || die
  47         for d in *conv; do
  48                 cd ${d} || die
  49                 local f=`echo ${d} | tr '[:upper:]' '[:lower:]'`
  50                 echo "all: $f" >> Makefile
  51                 if [ ${d} = CEFconv ] ; then
  52                         echo "all: cef5conv cefsconv" >> Makefile
  53                 fi
  54                 cd - || die
  55         done
  56         cd hbf2gf || die
  57         econf --with-kpathsea-lib="${EPREFIX}"/usr/$(get_libdir) \
  58                 --with-kpathsea-include="${EPREFIX}"/usr/include/kpathsea
  59 }
  60
  61 src_compile() {
  62         tc-export CC
  63         cd utils || die
  64         for d in *conv; do
  65                 cd ${d} || die
  66                 emake
  67                 cd - || die
  68         done
  69         cd hbf2gf || die
  70         emake
  71         cd - || die
  72
  73         if use emacs ; then
  74                 cd lisp || die
  75                 elisp-compile *.el
  76                 cd emacs || die
  77                 elisp-compile *.el
  78                 cd ../mule-2.3 || die
  79                 elisp-compile *.el
  80         fi
  81
  82         cd "${T}" || die
  83
  84         for f in "${S}"/texmf/hbf2gf/*.cfg ; do
  85         env TEXMFCNF="${EPREFIX}/etc/texmf/web2c" HBF_TARGET="${S}/texmf/fonts" "${S}/utils/hbf2gf/hbf2gf" $f || die
  86         done
  87
  88         einfo "Generating pk fonts"
  89         for gf in *.gf ; do
  90                 einfo "${gf}"
  91                 gftopk $gf || die
  92         done
  93 }
  94
  95 src_install() {
  96         cd utils || die
  97         for d in *conv; do
  98                 cd ${d} || die
  99                 local f=`echo $d | tr '[:upper:]' '[:lower:]'`
 100                 dobin *latex *conv
 101                 doman *.1
 102                 cd - || die
 103         done
 104         cd hbf2gf || die
 105         doman hbf2gf.1
 106         dobin hbf2gf
 107         dodir "${TEXMF}/fonts/hbf"
 108
 109         cd "${S}" || die
 110
 111         # Install pk fonts
 112         pushd texmf &>/dev/null || die
 113         for d in fonts/pk/modeless/*/* ; do
 114                 insinto ${TEXMF}/${d}
 115                 for f in "${T}"/${d##*/}*.pk ; do
 116                         newins ${f} `basename ${f/.pk/.500pk}`
 117                 done
 118         done
 119         popd &>/dev/null || die
 120
 121         insinto "${TEXMF}/tex/latex/${PN}"
 122         doins -r texinput
 123         doins -r contrib/wadalab
 124
 125         if use emacs ; then
 126                 cd utils/lisp || die
 127                 elisp-install ${PN} *.el{,c} emacs/*.el{,c} mule-2.3/*.el{,c}
 128         fi
 129
 130         cd "${S}" || die
 131
 132         # uwpatch stuff
 133         insinto ${TEXMF}/scripts/uwpatch
 134         doins uwpatch/uwpatchold.sh
 135         insinto ${TEXMF}/fonts/afm/uwpatch
 136         doins uwpatch/*.afm
 137
 138         # jisksp40 stuff
 139         insinto ${TEXMF}
 140         doins -r jisksp40/texmf
 141
 142         # kanji48 stuff
 143         insinto ${TEXMF}
 144         doins -r kanji48/texmf
 145
 146         use doc || rm -rf texmf/doc
 147         insinto ${TEXMF}
 148         doins -r texmf
 149
 150         # Move fonts because hbf2gf expects them in MISCFONTS
 151         mv "${ED}/${TEXMF}/fonts/hbf" "${ED}/${TEXMF}/fonts/misc" || die "mv font failed"
 152
 153         insinto ${TEXMF}/hbf2gf
 154         doins -r utils/hbf2gf/cfg/
 155
 156         insinto ${TEXMF}/scripts/subfonts
 157         doins -r utils/subfonts/
 158
 159         rm -f doc/COPYING doc/INSTALL || die
 160         dodoc ChangeLog README
 161         if use doc ; then
 162                 insinto /usr/share/doc/${PF}
 163                 doins -r doc
 164                 doins -r examples
 165         fi
 166         docinto uwpatch
 167         dodoc uwpatch/README
 168 }