dev-tcltk/tix/tix-8.4.3-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils multilib
   8
   9 MY_P="Tix${PV}"
  10 DESCRIPTION="A widget library for Tcl/Tk"
  11 HOMEPAGE="http://tix.sourceforge.net/"
  12 SRC_URI="mirror://sourceforge/tix/${MY_P}-src.tar.gz"
  13
  14 IUSE=""
  15 LICENSE="BSD"
  16 SLOT="0"
  17 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
  18
  19 RESTRICT="test"
  20
  21 DEPEND="
  22         dev-lang/tk:0=
  23         x11-libs/libX11
  24         x11-libs/libXau
  25         x11-libs/libXdmcp"
  26 RDEPEND="${DEPEND}"
  27
  28 S="${WORKDIR}/${MY_P}"
  29
  30 src_prepare() {
  31         (use x86-macos || use x64-macos) || epatch "${FILESDIR}"/${P}-link.patch
  32         sed \
  33                 -e 's:-Os::g' \
  34                 -i configure tclconfig/tcl.m4 || die
  35         epatch \
  36                 "${FILESDIR}"/${P}-tcl8.5.patch \
  37                 "${FILESDIR}"/${P}-tcl8.6.patch
  38 }
  39
  40 src_configure() {
  41         econf \
  42                 --with-tcl="${EPREFIX}/usr/$(get_libdir)" \
  43                 --with-tk="${EPREFIX}/usr/$(get_libdir)"
  44 }
  45
  46 src_install() {
  47         default
  48
  49         # Bug 168897
  50         doheader generic/tix.h
  51         # Bug 201138
  52         if use x86-macos || use x64-macos; then
  53                 mv "${ED}"/usr/$(get_libdir)/${MY_P}/libTix{,.}${PV}.dylib
  54                 dosym ${MY_P}/libTix.${PV}.dylib /usr/$(get_libdir)/libTix.${PV}.dylib
  55         else
  56                 dosym ${MY_P}/lib${MY_P}.so /usr/$(get_libdir)/lib${MY_P}.so
  57         fi
  58
  59         dodoc ChangeLog README.txt docs/*.txt
  60         dohtml -r index.html ABOUT.html docs/
  61 }