dev-tcltk/tcl3d/tcl3d-0.4.0-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit flag-o-matic multilib toolchain-funcs
   7
   8 DESCRIPTION="Tcl bindings to OpenGL and other 3D libraries"
   9 HOMEPAGE="http://www.tcl3d.org"
  10 SRC_URI="http://www.tcl3d.org/download/${P}.distrib/${PN}-src-${PV}.zip"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~amd64"
  15 IUSE="debug"
  16
  17 RDEPEND="
  18         dev-games/ode
  19         dev-lang/tk:0=
  20         dev-lang/tcl:0=
  21         media-libs/libsdl
  22         media-libs/ftgl
  23         virtual/opengl
  24         x11-libs/libXmu
  25 "
  26 DEPEND="${RDEPEND}
  27         >=dev-lang/swig-1.3.19"
  28
  29 S="${WORKDIR}/${PN}"
  30
  31 src_prepare() {
  32         TCL_VERSION=( $(echo 'puts [info tclversion]' | tclsh | tr '.' ' ') )
  33         einfo "Configuring for Tcl ${TCL_VERSION[0]}.${TCL_VERSION[1]}"
  34         sed -i \
  35                 -e 's:^\(TCLMAJOR\) *=\(.*\)$:\1 = '${TCL_VERSION[0]}':' \
  36                 -e 's:^\(TCLMINOR\) *=\(.*\)$:\1 = '${TCL_VERSION[1]}':' \
  37                 config_Linux* || die
  38
  39         # fix libSDL link
  40         sed -i \
  41                 -e 's:-lSDL-1\.2:-lSDL:g' \
  42                 tcl3dSDL/Makefile || die
  43 }
  44
  45 src_compile() {
  46         append-flags -mieee-fp -ffloat-store -fPIC
  47         use debug || append-flags -DNDEBUG
  48
  49         emake \
  50                 INSTDIR="/usr" OPT="${CFLAGS}" CC="$(tc-getCC) -c" \
  51                 CXX="$(tc-getCXX) -c" LD="$(tc-getLD)" \
  52                 WRAP_FTGL=1 WRAP_SDL=1 WRAP_GL2PS=0 WRAP_ODE=1
  53 }
  54
  55 src_install() {
  56         emake INSTDIR="${D}/usr" DESTDIR="${D}" INSTLIB="${D}/usr/$(get_libdir)" install
  57 }