dev-tcltk/itk/itk-4.0.1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit autotools eutils multilib versionator
   7
   8 MY_PV=${PV/_beta/b}
   9 ITCL_VERSION="$(get_version_component_range 1-2)"
  10
  11 DESCRIPTION="Object Oriented Enhancements for Tcl/Tk"
  12 HOMEPAGE="http://incrtcl.sourceforge.net/"
  13 SRC_URI="mirror://sourceforge/project/incrtcl/%5Bincr%20Tcl_Tk%5D-4-source/itk%20${MY_PV}/${PN}${MY_PV}.tar.gz"
  14 #SRC_URI="mirror://sourceforge/%5Bincr%20Tcl_Tk%5D-4-source/Itcl%20${MY_PV}/${PN}${MY_PV}.tar.gz"
  15
  16 IUSE=""
  17 SLOT="0"
  18 LICENSE="BSD"
  19 KEYWORDS="amd64 ia64 ppc sparc x86 ~amd64-linux ~x86-linux"
  20
  21 DEPEND="
  22         >=dev-lang/tk-8.6:=
  23         =dev-tcltk/itcl-${ITCL_VERSION}*"
  24 RDEPEND="${DEPEND}"
  25
  26 S="${WORKDIR}/${PN}${MY_PV}"
  27
  28 src_prepare() {
  29 #       epatch "${FILESDIR}"/${P}-install_data.patch
  30         mv configure.{in,ac} || die
  31         AT_M4DIR=.. eautoconf
  32         sed 's:-pipe::g' -i configure || die
  33 }
  34
  35 src_configure() {
  36         source "${EPREFIX}"/usr/$(get_libdir)/itcl${ITCL_VERSION}*/itclConfig.sh || die
  37         econf \
  38                 --with-tcl="${EPREFIX}"/usr/$(get_libdir) \
  39                 --with-tk="${EPREFIX}"/usr/$(get_libdir) \
  40                 --with-tclinclude="${EPREFIX}"/usr/include \
  41                 --with-tkinclude="${EPREFIX}"/usr/include \
  42                 --with-itcl="${ITCL_SRC_DIR}" \
  43                 --with-x
  44 }
  45
  46 src_compile() {
  47         emake CFLAGS_DEFAULT="${CFLAGS}"
  48 }
  49
  50 src_install() {
  51         default
  52
  53         dodoc license.terms
  54
  55         cat >> "${T}"/34${PN} <<- EOF
  56         LDPATH="${EPREFIX}/usr/$(get_libdir)/${PN}${MY_PV}/"
  57         EOF
  58         doenvd "${T}"/34${PN}
  59 }