dev-tcltk/blt/blt-2.4z-r13.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit autotools eutils flag-o-matic multilib toolchain-funcs
   8
   9 MY_V_SUFFIX="-8.5.2"
  10
  11 DESCRIPTION="Extension to Tk, adding new widgets, geometry managers, and misc commands"
  12 HOMEPAGE="
  13         http://blt.sourceforge.net/
  14         http://jos.decoster.googlepages.com/bltfortk8.5.2"
  15 SRC_URI="
  16         https://dev.gentoo.org/~jlec/distfiles/${PN}${PV}${MY_V_SUFFIX}.tar.gz
  17         http://jos.decoster.googlepages.com/${PN}${PV}${MY_V_SUFFIX}.tar.gz"
  18
  19 IUSE="jpeg static-libs X"
  20 SLOT="0"
  21 LICENSE="BSD"
  22 KEYWORDS="alpha amd64 ~arm hppa ia64 ~mips ~ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  23
  24 DEPEND="
  25         dev-lang/tk:0=
  26         jpeg? ( virtual/jpeg:0= )
  27         X? ( x11-libs/libX11 )"
  28 RDEPEND="${DEPEND}"
  29
  30 S="${WORKDIR}/${PN}${PV}${MY_V_SUFFIX}"
  31
  32 MAKEOPTS+=" -j1"
  33
  34 src_prepare() {
  35         epatch "${FILESDIR}/blt-2.4z-r4-fix-makefile2.patch"
  36         epatch "${FILESDIR}/blt-2.4z-r4-fix-makefile3.patch"
  37         # From blt-2.4z-6mdk.src.rpm
  38         epatch "${FILESDIR}"/blt2.4z-64bit.patch
  39
  40         epatch "${FILESDIR}"/blt-2.4z-tcl8.5-fixpkgruntime.patch
  41
  42         epatch "${FILESDIR}"/${P}-ldflags.patch
  43
  44         # Set the correct libdir and drop RPATH
  45         sed \
  46                 -e "s:\(^libdir=\${exec_prefix}/\)lib:\1$(get_libdir):" \
  47                 -e 's:LD_RUN_PATH=.*$:LD_RUN_PATH="":g' \
  48                 -e "/RANLIB/s:ranlib:$(tc-getRANLIB):g" \
  49                 -i configure* || die "sed configure* failed"
  50         sed \
  51                 -e "/^scriptdir =/s:lib:$(get_libdir):" \
  52                 -i Makefile.in demos/Makefile.in || die "sed Makefile.in failed"
  53
  54         sed \
  55                 -e "/AR/s:ar:$(tc-getAR):g" \
  56                 -e 's:0444:0644:g' \
  57                 -i src/Makefile.in || die
  58
  59         epatch \
  60                 "${FILESDIR}"/${P}-linking.patch \
  61                 "${FILESDIR}"/${P}-darwin.patch \
  62                 "${FILESDIR}"/${P}-gbsd.patch \
  63                 "${FILESDIR}"/${P}-tk8.6.patch \
  64                 "${FILESDIR}"/${P}-tcl8.6.patch \
  65                 "${FILESDIR}"/${P}-aclocal.patch
  66
  67         append-cflags -fPIC
  68
  69         mv configure.{in,ac} || die
  70
  71         eautoreconf
  72 }
  73
  74 src_configure() {
  75         LC_ALL=C \
  76         econf \
  77                 --x-includes="${EPREFIX}/usr/include" \
  78                 --x-libraries="${EPREFIX}/usr/$(get_libdir)" \
  79                 --with-blt="${EPREFIX}/usr/$(get_libdir)" \
  80                 --with-tcl="${EPREFIX}/usr/$(get_libdir)" \
  81                 --with-tk="${EPREFIX}/usr/$(get_libdir)" \
  82                 --with-tclincls="${EPREFIX}/usr/include" \
  83                 --with-tkincls="${EPREFIX}/usr/include" \
  84                 --with-tcllibs="${EPREFIX}/usr/$(get_libdir)" \
  85                 --with-tklibs="${EPREFIX}/usr/$(get_libdir)" \
  86                 --with-cc="$(tc-getCC)" \
  87                 --with-cflags="${CFLAGS}" \
  88                 --with-gnu-ld \
  89                 $(use_enable jpeg) \
  90                 $(use_with X x)
  91 }
  92
  93 src_compile() {
  94         emake LDFLAGS="${LDFLAGS}"
  95 }
  96
  97 src_install() {
  98         sed \
  99                 -e "s:\.\./src/bltwish:${EPREFIX}/usr/bin/bltwish:g" \
 100                 -e "s:\.\./bltwish:${EPREFIX}/usr/bin/bltwish:g" \
 101                 -e "s:/usr/local/bin/bltwish:${EPREFIX}/usr/bin/bltwish:g" \
 102                 -e "s:/usr/local/bin/tclsh:${EPREFIX}/usr/bin/tclsh:g" \
 103                 -i demos/{,scripts/}*.tcl || die
 104
 105         dodir \
 106                 /usr/bin \
 107                 /usr/$(get_libdir)/blt2.4/demos/bitmaps \
 108                 /usr/share/man/mann \
 109                 /usr/include
 110
 111         emake INSTALL_ROOT="${D}" install
 112
 113         dodoc NEWS PROBLEMS README
 114         dohtml html/*.html
 115         for f in `ls "${ED}"/usr/share/man/mann` ; do
 116                 mv "${ED}"/usr/share/man/mann/${f} "${ED}"/usr/share/man/mann/${f/.n/.nblt} || die
 117         done
 118
 119         # fix for linking against shared lib with -lBLT or -lBLTlite
 120         dosym libBLT24$(get_libname) /usr/$(get_libdir)/libBLT$(get_libname)
 121         dosym libBLTlite24$(get_libname) /usr/$(get_libdir)/libBLTlite$(get_libname)
 122
 123         use static-libs || \
 124                 find "${ED}"/usr/$(get_libdir) -name "*.a" -print0 | \
 125                 xargs -r -0 rm -fv
 126 }