dev-tcltk/blt/blt-2.4z-r12.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit autotools eutils flag-o-matic multilib toolchain-funcs
   8
   9 MY_V_SUFFIX="-8.5.2"
  10
  11 DESCRIPTION="Extension to Tk, adding new widgets, geometry managers, and misc commands"
  12 HOMEPAGE="
  13         http://blt.sourceforge.net/
  14         http://jos.decoster.googlepages.com/bltfortk8.5.2"
  15 SRC_URI="
  16         https://dev.gentoo.org/~jlec/distfiles/${PN}${PV}${MY_V_SUFFIX}.tar.gz
  17         http://jos.decoster.googlepages.com/${PN}${PV}${MY_V_SUFFIX}.tar.gz"
  18
  19 IUSE="jpeg static-libs X"
  20 SLOT="0"
  21 LICENSE="BSD"
  22 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  23
  24 DEPEND="
  25         dev-lang/tk
  26         jpeg? ( virtual/jpeg )
  27         X? ( x11-libs/libX11 )"
  28 RDEPEND="${DEPEND}"
  29
  30 S="${WORKDIR}/${PN}${PV}${MY_V_SUFFIX}"
  31
  32 MAKEOPTS+=" -j1"
  33
  34 src_prepare() {
  35         epatch "${FILESDIR}/blt-2.4z-r4-fix-makefile.patch"
  36         epatch "${FILESDIR}/blt-2.4z-r4-fix-makefile2.patch"
  37         # From blt-2.4z-6mdk.src.rpm
  38         epatch "${FILESDIR}"/blt2.4z-64bit.patch
  39
  40         #epatch "${FILESDIR}"/blt-2.4z-tcl8.5-fix.patch
  41         epatch "${FILESDIR}"/blt-2.4z-tcl8.5-fixpkgruntime.patch
  42
  43         epatch "${FILESDIR}"/${P}-ldflags.patch
  44
  45         # Set the correct libdir and drop RPATH
  46         sed \
  47                 -e "s:\(^libdir=\${exec_prefix}/\)lib:\1$(get_libdir):" \
  48                 -e 's:LD_RUN_PATH=.*$:LD_RUN_PATH="":g' \
  49                 -e "/RANLIB/s:ranlib:$(tc-getRANLIB):g" \
  50                 -i configure* || die "sed configure* failed"
  51         sed \
  52                 -e "/^scriptdir =/s:lib:$(get_libdir):" \
  53                 -i Makefile.in demos/Makefile.in || die "sed Makefile.in failed"
  54
  55         sed \
  56                 -e "/AR/s:ar:$(tc-getAR):g" \
  57                 -i src/Makefile.in || die
  58
  59         epatch \
  60                 "${FILESDIR}"/${P}-linking.patch \
  61                 "${FILESDIR}"/${P}-darwin.patch \
  62                 "${FILESDIR}"/${P}-gbsd.patch \
  63                 "${FILESDIR}"/${P}-tk8.6.patch \
  64                 "${FILESDIR}"/${P}-tcl8.6.patch \
  65                 "${FILESDIR}"/${P}-aclocal.patch
  66
  67         append-cflags -fPIC
  68
  69         eautoreconf
  70 }
  71
  72 src_configure() {
  73         LC_ALL=C \
  74         econf \
  75                 --x-includes="${EPREFIX}/usr/include" \
  76                 --x-libraries="${EPREFIX}/usr/$(get_libdir)" \
  77                 --with-blt="${EPREFIX}/usr/$(get_libdir)" \
  78                 --with-tcl="${EPREFIX}/usr/$(get_libdir)" \
  79                 --with-tk="${EPREFIX}/usr/$(get_libdir)" \
  80                 --with-tclincls="${EPREFIX}/usr/include" \
  81                 --with-tkincls="${EPREFIX}/usr/include" \
  82                 --with-tcllibs="${EPREFIX}/usr/$(get_libdir)" \
  83                 --with-tklibs="${EPREFIX}/usr/$(get_libdir)" \
  84                 --with-cc="$(tc-getCC)" \
  85                 --with-cflags="${CFLAGS}" \
  86                 --with-gnu-ld \
  87                 $(use_enable jpeg) \
  88                 $(use_with X x)
  89 }
  90
  91 src_compile() {
  92         # parallel borks
  93         emake LDFLAGS="${LDFLAGS}"
  94 }
  95
  96 src_install() {
  97         sed \
  98                 -e "s:\.\./src/bltwish:${EPREFIX}/usr/bin/bltwish:g" \
  99                 -e "s:\.\./bltwish:${EPREFIX}/usr/bin/bltwish:g" \
 100                 -e "s:/usr/local/bin/bltwish:${EPREFIX}/usr/bin/bltwish:g" \
 101                 -e "s:/usr/local/bin/tclsh:${EPREFIX}/usr/bin/tclsh:g" \
 102                 -i demos/{,scripts/}*.tcl || die
 103
 104         dodir /usr/bin \
 105                 /usr/$(get_libdir)/blt2.4/demos/bitmaps \
 106                 /usr/share/man/mann \
 107                 /usr/include
 108
 109         emake INSTALL_ROOT="${D}" install || die "make install failed"
 110
 111         dodoc NEWS PROBLEMS README
 112         dohtml html/*.html
 113         for f in `ls "${ED}"/usr/share/man/mann` ; do
 114                 mv "${ED}"/usr/share/man/mann/${f} "${ED}"/usr/share/man/mann/${f/.n/.nblt}
 115         done
 116
 117         # bug 259338 - dev-tcltk/blt-2.4z-r4 provides empty pkgIndex.tcl
 118         cp "${FILESDIR}"/pkgIndex.tcl "${ED}"/usr/$(get_libdir)/blt2.4/pkgIndex.tcl
 119
 120         # fix for linking against shared lib with -lBLT or -lBLTlite
 121         dosym libBLT24$(get_libname) /usr/$(get_libdir)/libBLT$(get_libname)
 122         dosym libBLTlite24$(get_libname) /usr/$(get_libdir)/libBLTlite$(get_libname)
 123
 124         use static-libs || \
 125                 find "${ED}"/usr/$(get_libdir) -name "*.a" -print0 | \
 126                 xargs -r -0 rm -fv
 127 }