dev-ruby/websocket-driver/websocket-driver-0.7.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 USE_RUBY="ruby23 ruby24 ruby25 ruby26"
   6
   7 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
   8 RUBY_FAKEGEM_TASK_DOC=""
   9 RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
  10
  11 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  12
  13 inherit ruby-fakegem
  14
  15 DESCRIPTION="A complete implementation of the WebSocket protocols"
  16 HOMEPAGE="https://github.com/faye/websocket-driver-ruby"
  17 SRC_URI="https://github.com/faye/websocket-driver-ruby/archive/${PV}.tar.gz -> ${P}.tar.gz"
  18 RUBY_S="${PN}-ruby-${PV}"
  19
  20 LICENSE="MIT"
  21 SLOT="0.7"
  22 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
  23 IUSE=""
  24
  25 ruby_add_rdepend ">=dev-ruby/websocket-extensions-0.1.0"
  26
  27 all_ruby_prepare() {
  28         sed -i -e '/bundler/ s:^:#:' spec/spec_helper.rb || die
  29 }
  30
  31 each_ruby_configure() {
  32         ${RUBY} -Cext/websocket-driver extconf.rb || die
  33 }
  34
  35 each_ruby_compile() {
  36         emake V=1 -Cext/websocket-driver
  37         cp ext/websocket-driver/websocket_mask.so lib/ || die
  38 }