dev-ruby/unf_ext/unf_ext-0.0.7.7.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 USE_RUBY="ruby24 ruby25 ruby26 ruby27"
   7
   8 RUBY_FAKEGEM_RECIPE_TEST="none"
   9
  10 RUBY_FAKEGEM_DOCDIR="doc"
  11
  12 RUBY_FAKEGEM_EXTRADOC="README.md"
  13
  14 inherit ruby-fakegem multilib
  15
  16 DESCRIPTION="Unicode Normalization Form support library for CRuby"
  17 HOMEPAGE="https://github.com/knu/ruby-unf_ext"
  18
  19 LICENSE="MIT"
  20 SLOT="0"
  21 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  22 IUSE="doc test"
  23
  24 ruby_add_bdepend "
  25         test? (
  26                 >=dev-ruby/test-unit-2.5.1-r1
  27         )"
  28
  29 all_ruby_prepare() {
  30         sed -i -e '/bundler/,/end/ s:^:#:' Rakefile test/helper.rb || die
  31 }
  32
  33 each_ruby_configure() {
  34         ${RUBY} -Cext/unf_ext extconf.rb || die
  35 }
  36
  37 each_ruby_compile() {
  38         emake -Cext/unf_ext CFLAGS="${CFLAGS} -fPIC" archflag="${LDFLAGS}" V=1
  39         cp ext/unf_ext/*$(get_modname) lib/ || die
  40 }
  41
  42 each_ruby_test() {
  43         ruby-ng_testrb-2 test/test_*.rb
  44 }