dev-ruby/rspec-expectations/rspec-expectations-3.3.1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 USE_RUBY="ruby20 ruby21 ruby22"
   6
   7 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
   8
   9 RUBY_FAKEGEM_TASK_DOC=""
  10 RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md"
  11
  12 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  13
  14 inherit ruby-fakegem
  15
  16 DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
  17 HOMEPAGE="https://github.com/rspec/rspec-expectations"
  18 SRC_URI="https://github.com/rspec/${PN}/archive/v${PV}.tar.gz -> ${P}-git.tgz"
  19
  20 LICENSE="MIT"
  21 SLOT="3"
  22 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  23 IUSE=""
  24
  25 SUBVERSION="$(get_version_component_range 1-2)"
  26
  27 ruby_add_rdepend ">=dev-ruby/diff-lcs-1.2.0 <dev-ruby/diff-lcs-2
  28         =dev-ruby/rspec-support-${SUBVERSION}*"
  29
  30 ruby_add_bdepend "test? (
  31                 >=dev-ruby/rspec-mocks-3.2.0:3
  32         )"
  33
  34 all_ruby_prepare() {
  35         # Don't set up bundler: it doesn't understand our setup.
  36         sed -i -e '/[Bb]undler/d' Rakefile || die
  37
  38         # Remove the Gemfile to avoid running through 'bundle exec'
  39         rm Gemfile || die
  40
  41         # fix up the gemspecs
  42         sed -i \
  43                 -e '/git ls/d' \
  44                 -e '/add_development_dependency/d' \
  45                 "${RUBY_FAKEGEM_GEMSPEC}" || die
  46
  47         #
  48         sed -i -e '1irequire "spec_helper"' spec/rspec/expectations/configuration_spec.rb || die
  49
  50         # Avoid a weird, and failing, test testing already installed code.
  51         sed -e '/has an up-to-date caller_filter file/,/end/ s:^:#:' -i spec/rspec/expectations_spec.rb || die
  52 }
  53
  54 each_ruby_prepare() {
  55         case ${RUBY} in
  56                 *ruby22)
  57                         # The rubygems version bundled with ruby 2.2 causes warnings.
  58                         sed -i -e '/a library that issues no warnings when loaded/,/^  end/ s:^:#:' spec/rspec/expectations_spec.rb || die
  59                         ;;
  60         esac
  61 }