dev-ruby/rspec-expectations/rspec-expectations-2.99.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 USE_RUBY="ruby21 ruby22 ruby23 ruby24"
   6
   7 RUBY_FAKEGEM_RECIPE_TEST="rspec"
   8
   9 RUBY_FAKEGEM_TASK_DOC=""
  10 RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md"
  11
  12 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  13
  14 inherit ruby-fakegem
  15
  16 DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
  17 HOMEPAGE="http://rspec.rubyforge.org/"
  18 SRC_URI="https://github.com/rspec/${PN}/archive/v${PV}.tar.gz -> ${P}-git.tgz"
  19
  20 LICENSE="MIT"
  21 SLOT="2"
  22 KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ia64 ppc ppc64 ~sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  23 IUSE=""
  24
  25 ruby_add_rdepend ">=dev-ruby/diff-lcs-1.1.3"
  26
  27 ruby_add_bdepend "test? (
  28                 >=dev-ruby/rspec-core-2.99.0:2
  29                 >=dev-ruby/rspec-mocks-2.14.0:2
  30         )"
  31
  32 all_ruby_prepare() {
  33         # Don't set up bundler: it doesn't understand our setup.
  34         sed -i -e '/[Bb]undler/d' Rakefile || die
  35
  36         # Remove the Gemfile to avoid running through 'bundle exec'
  37         rm Gemfile || die
  38
  39         # Remove .rspec options to avoid dependency on newer rspec when
  40         # bootstrapping.
  41         rm .rspec || die
  42
  43         # fix up the gemspecs
  44         sed -i \
  45                 -e '/git ls/d' \
  46                 -e '/add_development_dependency/d' \
  47                 "${RUBY_FAKEGEM_GEMSPEC}" || die
  48
  49         # Avoid a weird, and failing, test testing already installed code.
  50         sed -e '/has an up-to-date caller_filter file/,/end/ s:^:#:' -i spec/rspec/expectations_spec.rb || die
  51 }
  52
  53 each_ruby_prepare() {
  54         case ${RUBY} in
  55                 *ruby24)
  56                         sed -i -e 's/of Fixnum/of Integer/' spec/rspec/expectations/expectation_target_spec.rb spec/rspec/matchers/be_instance_of_spec.rb || die
  57                         ;;
  58         esac
  59 }