dev-ruby/roadie-rails/roadie-rails-2.1.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 USE_RUBY="ruby25 ruby26"
   7 RUBY_FAKEGEM_EXTRADOC="README.md"
   8 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
   9 RUBY_FAKEGEM_RECIPE_DOC="yard"
  10
  11 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  12
  13 inherit ruby-fakegem
  14
  15 DESCRIPTION="Hooks Roadie into your Rails application to help with email generation"
  16 HOMEPAGE="https://github.com/Mange/roadie-rails"
  17 SRC_URI="https://github.com/Mange/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  18
  19 LICENSE="MIT"
  20 SLOT="$(ver_cut 1)"
  21 KEYWORDS="~amd64"
  22 IUSE=""
  23
  24 #RESTRICT="test"
  25
  26 ruby_add_rdepend ">=dev-ruby/roadie-3.1
  27         || ( dev-ruby/railties:6.0 dev-ruby/railties:5.2 )"
  28 ruby_add_bdepend "
  29         test? (
  30                 dev-ruby/bundler
  31                 dev-ruby/rspec-rails
  32                 dev-ruby/rspec-collection_matchers )"
  33
  34 all_ruby_prepare() {
  35         sed -i -e '/codecov/ s:^:#:' Gemfile || die
  36         sed -i -e 's/git ls-files/find . -print/' ${RUBY_FAKEGEM_GEMSPEC} || die
  37
  38         # Avoid already removed rails version
  39         sed -i -e '/rails_51/ s:^:#:' spec/integration_spec.rb || die
  40 }
  41
  42 each_ruby_test() {
  43         ${RUBY} -S bundle exec rspec-3 spec || die
  44 }