dev-ruby/regexp_parser/regexp_parser-0.5.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 USE_RUBY="ruby24 ruby25 ruby26 ruby27"
   6
   7 RUBY_FAKEGEM_RECIPE_DOC="rdoc"
   8 RUBY_FAKEGEM_EXTRADOC="ChangeLog README.md"
   9
  10 RUBY_FAKEGEM_BINWRAP=""
  11
  12 inherit ruby-fakegem
  13
  14 DESCRIPTION="A library for tokenizing, lexing, and parsing Ruby regular expressions"
  15 HOMEPAGE="https://github.com/ammar/regexp_parser"
  16 SRC_URI="https://github.com/ammar/regexp_parser/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  17
  18 LICENSE="MIT"
  19 SLOT="0"
  20 KEYWORDS="~amd64 ~arm ~x86"
  21 IUSE=""
  22
  23 DEPEND+=" =dev-util/ragel-6*"
  24
  25 ruby_add_bdepend "dev-ruby/rake"
  26
  27 all_ruby_prepare() {
  28         sed -i -e '/bundler/I s:^:#:' Rakefile || die
  29         sed -i -e '1irequire "delegate"' test/support/warning_extractor.rb || die
  30 }
  31
  32 each_ruby_compile() {
  33         ${RUBY} -S rake ragel:rb || die
  34 }
  35
  36 each_ruby_test() {
  37         ${RUBY} -Ilib bin/test || die
  38 }