dev-ruby/rcairo/rcairo-1.16.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 USE_RUBY="ruby23 ruby24 ruby25 ruby26"
   7
   8 RUBY_FAKEGEM_NAME="cairo"
   9
  10 RUBY_FAKEGEM_RECIPE_DOC="rdoc"
  11
  12 RUBY_FAKEGEM_TASK_TEST=""
  13
  14 RUBY_FAKEGEM_DOCDIR="doc"
  15
  16 RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"
  17
  18 inherit multilib ruby-fakegem
  19
  20 DESCRIPTION="Ruby bindings for cairo"
  21 HOMEPAGE="https://cairographics.org/rcairo/"
  22
  23 IUSE=""
  24
  25 SLOT="0"
  26 LICENSE="|| ( Ruby GPL-2 )"
  27 KEYWORDS="amd64 ~ppc ~x86"
  28
  29 RDEPEND="${RDEPEND}
  30         >=x11-libs/cairo-1.2.0[svg]"
  31 DEPEND="${DEPEND}
  32         >=x11-libs/cairo-1.2.0[svg]"
  33
  34 ruby_add_bdepend "
  35         >=dev-ruby/pkg-config-1.2.2
  36         dev-ruby/ruby-glib2
  37         test? ( >=dev-ruby/test-unit-2.1.0-r1:2 dev-ruby/ruby-poppler )"
  38
  39 all_ruby_prepare() {
  40         # Avoid unneeded dependency
  41         sed -i -e '/native-package-installer/ s:^:#:' ext/cairo/extconf.rb || die
  42         sed -i -e '/native-package-installer/,/Gem::Dependency/ d' ../metadata || die
  43
  44         # Avoid test that requires unpackaged fixture
  45         sed -i -e '/sub_test_case..FreeTypeFontFace/,/^  end/ s:^:#:' test/test_font_face.rb || die
  46 }
  47
  48 each_ruby_configure() {
  49         ${RUBY} -Cext/cairo extconf.rb || die "extconf failed"
  50 }
  51
  52 each_ruby_compile() {
  53         emake V=1 -Cext/cairo
  54
  55         # again, try to make it more standard, to install it more easily.
  56         cp ext/cairo/cairo$(get_modname) lib/ || die
  57 }
  58
  59 each_ruby_test() {
  60         # don't rely on the Rakefile because it's a mess to load with
  61         # their hierarchy, do it manually.
  62         ${RUBY} -Ilib -r ./test/helper \
  63                 -e 'gem "test-unit"; require "test/unit"; Dir.glob("test/**/test_*.rb") {|f| load f}' || die "tests failed"
  64 }
  65
  66 each_ruby_install() {
  67         each_fakegem_install
  68
  69         insinto $(ruby_get_hdrdir)
  70         doins ext/cairo/rb_cairo.h
  71 }
  72
  73 all_ruby_install() {
  74         all_fakegem_install
  75
  76         insinto /usr/share/doc/${PF}/samples
  77         doins -r samples/*
  78 }