dev-ruby/rake/rake-13.0.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 USE_RUBY="ruby24 ruby25 ruby26"
   6
   7 RUBY_FAKEGEM_RECIPE_DOC="none"
   8 RUBY_FAKEGEM_EXTRADOC="CHANGES README.rdoc TODO"
   9
  10 RUBY_FAKEGEM_TASK_TEST=""
  11
  12 RUBY_FAKEGEM_BINDIR="exe"
  13
  14 RUBY_FAKEGEM_GEMSPEC="rake.gemspec"
  15
  16 inherit bash-completion-r1 ruby-fakegem
  17
  18 DESCRIPTION="Make-like scripting in Ruby"
  19 HOMEPAGE="https://github.com/ruby/rake"
  20 SRC_URI="https://github.com/ruby/rake/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  21
  22 LICENSE="MIT"
  23 SLOT="0"
  24 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  25 IUSE="doc"
  26
  27 DEPEND+=" app-arch/gzip"
  28
  29 ruby_add_bdepend "test? ( >=dev-ruby/minitest-5.8 )
  30         doc? ( dev-ruby/rdoc )"
  31
  32 all_ruby_prepare() {
  33         sed -i -e 's/git ls-files -z/find . -print0/' ${RUBY_FAKEGEM_GEMSPEC} || die
  34 }
  35
  36 all_ruby_compile() {
  37         if use doc; then
  38                 rdoc --title "Rake - Ruby Make" --main README.rdoc --out html lib *.rdoc doc/*/*.rdoc || die
  39                 rm -f html/js/*.js.gz
  40         fi
  41 }
  42
  43 each_ruby_test() {
  44         ${RUBY} -Ilib:test:. -e 'gem "minitest", "~>5.8"; require "minitest/autorun"; Dir["test/test_*.rb"].each{|f| require f}' || die
  45 }
  46
  47 all_ruby_install() {
  48         ruby_fakegem_binwrapper rake
  49
  50         if use doc; then
  51                 pushd html
  52                 dodoc -r *
  53                 popd
  54         fi
  55
  56         doman doc/rake.1
  57
  58         newbashcomp "${FILESDIR}"/rake.bash-completion ${PN}
  59 }