dev-ruby/rack-test/rack-test-1.1.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 USE_RUBY="ruby24 ruby25 ruby26 ruby27"
   6
   7 RUBY_FAKEGEM_RECIPE_DOC="rdoc"
   8
   9 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
  10
  11 RUBY_FAKEGEM_EXTRADOC="History.md README.md"
  12
  13 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  14
  15 inherit ruby-fakegem
  16
  17 DESCRIPTION="Rack::Test is a small, simple testing API for Rack apps"
  18 HOMEPAGE="https://github.com/rack-test/rack-test"
  19 SRC_URI="https://github.com/rack-test/rack-test/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  20
  21 LICENSE="MIT"
  22 SLOT="1.0"
  23 KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
  24 IUSE=""
  25
  26 ruby_add_rdepend ">=dev-ruby/rack-1.0:* <dev-ruby/rack-3:*"
  27 ruby_add_bdepend "
  28         test? ( dev-ruby/sinatra:2 dev-ruby/rack:2.0 )"
  29
  30 all_ruby_prepare() {
  31         rm Gemfile* || die
  32         sed -i -e '/bundler/d' -e '/[Cc]ode[Cc]limate/d' -e '/simplecov/,/^end/ s:^:#:' spec/spec_helper.rb || die
  33 }