dev-ruby/prawn/prawn-1.2.1-r2.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 USE_RUBY="ruby19 ruby20 ruby21"
   7
   8 RUBY_FAKEGEM_RECIPE_DOC="yard"
   9 RUBY_FAKEGEM_RECIPE_TEST="rspec"
  10 RUBY_FAKEGEM_EXTRAINSTALL="VERSION data"
  11
  12 inherit ruby-fakegem
  13
  14 DESCRIPTION="Fast, Nimble PDF Generation For Ruby"
  15 HOMEPAGE="http://prawn.majesticseacreature.com/"
  16 SRC_URI="https://github.com/prawnpdf/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  17 LICENSE="|| ( GPL-2 Ruby )"
  18 SLOT="1"
  19 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
  20 IUSE=""
  21
  22 ruby_add_rdepend "dev-ruby/pdf-core
  23         >=dev-ruby/ttfunk-1.2.0"
  24 ruby_add_bdepend "test? ( dev-ruby/coderay
  25         dev-ruby/mocha
  26         >=dev-ruby/pdf-inspector-1.1.0
  27         >=dev-ruby/pdf-reader-1.2
  28         )"
  29
  30 all_ruby_prepare() {
  31         sed -i -e "/[Bb]undler/d" Rakefile spec/spec_helper.rb || die
  32         # Remove failing tests
  33         # https://github.com/prawnpdf/prawn/pull/693
  34         # https://github.com/prawnpdf/prawn/issues/603
  35         sed -i -e "/should process UTF-8 chars/,+9 s/^/#/" spec/line_wrap_spec.rb || die
  36         sed -i -e "/shrink_to_fit with special utf-8 text/,+12 s/^/#/" spec/text_spec.rb || die
  37 }