dev-ruby/net-ssh/net-ssh-4.2.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 USE_RUBY="ruby23 ruby24 ruby25 ruby26"
   7
   8 RUBY_FAKEGEM_DOCDIR="doc"
   9 RUBY_FAKEGEM_EXTRADOC="CHANGES.txt README.rdoc THANKS.txt"
  10 RUBY_FAKEGEM_EXTRAINSTALL="support"
  11
  12 inherit ruby-fakegem
  13
  14 DESCRIPTION="Non-interactive SSH processing in pure Ruby"
  15 HOMEPAGE="https://github.com/net-ssh/net-ssh"
  16 SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> net-ssh-git-${PV}.tgz"
  17
  18 LICENSE="GPL-2"
  19 SLOT="4"
  20 KEYWORDS="amd64 ~arm ppc ppc64 x86"
  21 IUSE="sodium test"
  22
  23 ruby_add_rdepend "virtual/ruby-ssl sodium? ( dev-ruby/rbnacl:4 dev-ruby/bcrypt_pbkdf )"
  24 ruby_add_bdepend "test? ( dev-ruby/test-unit:2 >=dev-ruby/mocha-0.13 )"
  25
  26 all_ruby_prepare() {
  27         # Don't use a ruby-bundled version of libsodium
  28         sed -i -e '/rbnacl\/libsodium/ s:^:#:' lib/net/ssh/authentication/ed25519.rb || die
  29
  30         # Don' try to use libsodium-related tests with USE=-sodium
  31         if ! use sodium ; then
  32                 rm -f test/authentication/test_ed25519.rb
  33         fi
  34
  35         # Avoid bundler dependency
  36         sed -i -e '/\(bundler\|:release\)/ s:^:#:' Rakefile || die
  37 }