dev-ruby/mysql2/mysql2-0.5.2-r3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 USE_RUBY="ruby23 ruby24 ruby25 ruby26"
   6
   7 # Tests require a live MySQL database but should all pass.
   8 RUBY_FAKEGEM_TASK_TEST=""
   9
  10 RUBY_FAKEGEM_TASK_DOC=""
  11
  12 RUBY_FAKEGEM_EXTRADOC="README.md"
  13
  14 inherit multilib ruby-fakegem
  15
  16 DESCRIPTION="A modern, simple and very fast Mysql library for Ruby - binding to libmysql"
  17 HOMEPAGE="https://github.com/brianmario/mysql2"
  18
  19 LICENSE="MIT"
  20 SLOT="0.5"
  21 KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
  22 IUSE="mysql mariadb"
  23 REQUIRED_USE="^^ ( mariadb mysql )"
  24
  25 MDEPEND="mysql? ( dev-db/mysql-connector-c:= ) mariadb? ( dev-db/mariadb-connector-c:= )"
  26 DEPEND="${DEPEND} ${MDEPEND}"
  27 RDEPEND="${RDEPEND} ${MDEPEND}"
  28
  29 each_ruby_configure() {
  30         local config
  31         if use mysql ; then
  32                 config="${EPREFIX}/usr/bin/mysql_config"
  33         fi
  34         if use mariadb ; then
  35                 config="${EPREFIX}/usr/bin/mariadb_config"
  36         fi
  37
  38         ${RUBY} -Cext/mysql2 extconf.rb --with-mysql-config="${config}" || die
  39 }
  40
  41 each_ruby_compile() {
  42         emake V=1 -Cext/mysql2
  43         cp ext/mysql2/mysql2$(get_modname) lib/mysql2/ || die
  44 }