dev-ruby/listen/listen-3.1.5-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 USE_RUBY="ruby21 ruby22 ruby23 ruby24"
   7
   8 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
   9
  10 RUBY_FAKEGEM_TASK_DOC=""
  11 RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
  12
  13 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  14
  15 inherit ruby-fakegem
  16
  17 SRC_URI="https://github.com/guard/listen/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  18 DESCRIPTION="Listens to file modifications and notifies you about the changes"
  19 HOMEPAGE="https://github.com/guard/listen"
  20
  21 LICENSE="MIT"
  22 SLOT="3"
  23 KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
  24 IUSE="test"
  25
  26 # Block on other packages trying to install a /usr/bin/listen
  27 RDEPEND+="!!media-sound/listen !!media-radio/ax25 !!<dev-ruby/listen-2.8.6-r1:2"
  28
  29 ruby_add_rdepend ">=dev-ruby/rb-inotify-0.9.7 >=dev-ruby/ruby_dep-1.2:1"
  30
  31 ruby_add_bdepend "test? ( dev-ruby/thor )"
  32
  33 all_ruby_prepare() {
  34         rm -f Gemfile || die
  35         sed -i -e "/git/,+3d" -e "/rb-fsevent/d" ${PN}.gemspec || die
  36         sed -i -e "/rb-fsevent/d"  lib/listen/adapter/darwin.rb || die
  37         rm -rf spec/lib/listen/adapter/darwin_spec.rb || die
  38 }
  39
  40 each_ruby_prepare() {
  41         mkdir spec/.fixtures || die
  42 }
  43
  44 each_ruby_test() {
  45         RSPEC_VERSION=3 ruby-ng_rspec
  46         rm -rf spec/.fixtures || die
  47 }