dev-ruby/gruff/gruff-0.8.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 USE_RUBY="ruby24 ruby25 ruby26 ruby27"
   6
   7 RUBY_FAKEGEM_TASK_DOC=""
   8
   9 RUBY_FAKEGEM_DOCDIR="doc"
  10 RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
  11
  12 RUBY_FAKEGEM_EXTRAINSTALL="assets rails_generators"
  13
  14 RUBY_FAKEGEM_GEMSPEC="gruff.gemspec"
  15
  16 inherit ruby-fakegem
  17
  18 DESCRIPTION="Beautiful graphs for one or multiple datasets"
  19 HOMEPAGE="https://github.com/topfunky/gruff"
  20 SRC_URI="https://github.com/topfunky/gruff/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  21
  22 LICENSE="MIT"
  23 SLOT="0"
  24 KEYWORDS="~amd64 ~x86 ~x86-macos"
  25 IUSE=""
  26
  27 # imagemagick is an indirect dependency through rmagick. However, for
  28 # gruff to work properly imagemagick needs to be compiled with truetype
  29 # support and this cannot be expressed in the rmagick dependency. Tests
  30 # also require imagemagick to have jpeg and png support.
  31 DEPEND="${DEPEND} test? ( media-gfx/imagemagick[jpeg,png,truetype,webp] )"
  32 RDEPEND="${RDEPEND} media-gfx/imagemagick[truetype]"
  33
  34 ruby_add_rdepend "dev-ruby/rmagick:*"
  35 ruby_add_bdepend "
  36         test? (
  37                 dev-ruby/test-unit
  38         )"
  39
  40 all_ruby_prepare() {
  41         sed -i -e '/reporters/I s:^:#:' test/gruff_test_case.rb || die
  42         sed -i -e '2irequire "date"' test/test_scatter.rb || die
  43
  44         sed -e 's/git ls-files/find . -print/' \
  45                 -i ${RUBY_FAKEGEM_GEMSPEC} || die
  46 }
  47
  48 each_ruby_test() {
  49         ${RUBY} -Ilib:. -e "Dir['test/test_*.rb'].each{|f| require f}" || die
  50 }