dev-ruby/fast_gettext/fast_gettext-1.6.0.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 USE_RUBY="ruby23 ruby24 ruby25"
   7
   8 RUBY_FAKEGEM_TASK_DOC=""
   9 RUBY_FAKEGEM_EXTRADOC="CHANGELOG Readme.md"
  10
  11 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
  12
  13 inherit ruby-fakegem
  14
  15 DESCRIPTION="GetText but 3.5x faster, 560x less memory, clean namespace and threadsave!"
  16 HOMEPAGE="https://github.com/grosser/fast_gettext"
  17 SRC_URI="https://github.com/grosser/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  18
  19 LICENSE="public-domain"
  20 SLOT="0"
  21 KEYWORDS="amd64 ~arm ~hppa ~ppc ~ppc64 x86"
  22 IUSE=""
  23
  24 ruby_add_bdepend "test? ( dev-ruby/bundler )"
  25
  26 all_ruby_prepare() {
  27         rm Gemfile.lock || die
  28
  29         # Remove jeweler and bump from Gemfile since they are not needed for tests.
  30         sed -i -e '/jeweler/d' -e '/bump/d' -e '/appraisal/d' Gemfile || die
  31
  32         # Avoid unneeded dependency on git and development dependencies.
  33         sed -e '/git ls-files/ s:^:#:' \
  34                 -e '/\(wwtd\|bump\|sqlite3\|activerecord\|i18n\)/ s:^:#:' \
  35                 -i fast_gettext.gemspec || die
  36
  37         # Avoid a test dependency on activerecord since this is now in the
  38         # dependency tree for app-admin/puppet and many arches don't have
  39         # rails keyworded.
  40         sed -i -e '/active_record/ s:^:#:' spec/spec_helper.rb || die
  41         rm -f spec/fast_gettext/translation_repository/db_spec.rb || die
  42         sed -i -e '/works with DB repository/,/^    end/ s:^:#:' spec/fast_gettext/storage_spec.rb || die
  43         sed -i -e '/with i18n loaded/,/^  end/ s:^:#:' spec/fast_gettext/vendor/string_spec.rb || die
  44
  45         # Don't run a test that requires safe mode which we can't provide
  46         # due to insecure directory settings for the portage dir. This spec
  47         # also calls out to ruby which won't work with different ruby
  48         # implementations.
  49         sed -i -e '/can work in SAFE mode/,/^  end/ s:^:#:' spec/fast_gettext/translation_repository/mo_spec.rb || die
  50 }
  51
  52 each_ruby_prepare() {
  53         # Make sure the right ruby interpreter is used
  54         sed -i -e "s:bundle exec ruby:bundle exec ${RUBY}:" spec/fast_gettext/vendor/*spec.rb || die
  55 }