dev-ruby/childprocess/childprocess-1.0.1-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 USE_RUBY="ruby24 ruby25 ruby26"
   7
   8 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
   9
  10 RUBY_FAKEGEM_RECIPE_DOC="rdoc"
  11 RUBY_FAKEGEM_EXTRADOC="README.md"
  12
  13 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  14
  15 inherit ruby-fakegem
  16
  17 DESCRIPTION="Solution for controlling external programs running in the background"
  18 HOMEPAGE="https://github.com/jarib/childprocess"
  19
  20 LICENSE="MIT"
  21 SLOT="2"
  22 KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86"
  23 IUSE=""
  24
  25 ruby_add_rdepend ">=dev-ruby/ffi-1.0.11"
  26
  27 all_ruby_prepare() {
  28         eapply "${FILESDIR}/${P}-ruby26-reopen.patch"
  29
  30         # Remove bundler support
  31         rm Gemfile || die
  32         sed -i -e "/[Bb]undler/d" Rakefile || die
  33         sed -i -e "/[Cc]overalls/d" spec/spec_helper.rb || die
  34         sed -i -e 's/git ls-files/find/' ${RUBY_FAKEGEM_GEMSPEC} || die
  35 }
  36
  37 each_ruby_prepare() {
  38         sed -i -e "s:'ruby':'"${RUBY}"':" spec/childprocess_spec.rb || die
  39 }
  40
  41 each_ruby_test() {
  42         RUBYLIB=lib RSPEC_VERSION=3 ruby-ng_rspec
  43 }