dev-ruby/charlock_holmes/charlock_holmes-0.7.6.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 USE_RUBY="ruby23 ruby24 ruby25 ruby26"
   6
   7 RUBY_FAKEGEM_RECIPE_DOC="rdoc"
   8 RUBY_FAKEGEM_EXTRADOC="README.md"
   9
  10 inherit ruby-fakegem
  11
  12 DESCRIPTION="Character encoding detecting library for Ruby using ICU"
  13 HOMEPAGE="https://github.com/brianmario/charlock_holmes"
  14 SRC_URI="https://github.com/brianmario/charlock_holmes/archive/${PV}.tar.gz -> ${P}.tar.gz"
  15
  16 LICENSE="MIT"
  17 SLOT="0"
  18 KEYWORDS="~amd64"
  19 IUSE="test"
  20
  21 ruby_add_bdepend "test? (
  22         dev-ruby/minitest )"
  23
  24 CDEPEND="dev-libs/icu:=
  25                 sys-libs/zlib"
  26 DEPEND+=" ${CDEPEND}"
  27 RDEPEND+=" ${CDEPEND}"
  28
  29 PATCHES=( "${FILESDIR}"/${PN}-0.7.6-gcc5.patch )
  30
  31 all_ruby_prepare() {
  32         sed -i -e '/bundler/d' test/helper.rb || die
  33
  34         # Avoid dependency on rake-compiler
  35         sed -i -e '/rake-compiler/,$ s:^:#:' Rakefile || die
  36 }
  37
  38 each_ruby_configure() {
  39         ${RUBY} -Cext/${PN} extconf.rb || die
  40 }
  41
  42 each_ruby_compile() {
  43         emake V=1 -Cext/${PN}
  44         cp ext/${PN}/${PN}$(get_modname) lib/${PN}/ || die
  45 }
  46
  47 each_ruby_test() {
  48         ${RUBY} -Ilib test/*.rb || die
  49 }