dev-ruby/bcat/bcat-0.6.2-r2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 USE_RUBY="ruby19 ruby20 ruby21 ruby22"
   7
   8 RUBY_FAKEGEM_TASK_DOC="man"
   9 RUBY_FAKEGEM_EXTRADOC="README"
  10
  11 inherit ruby-fakegem
  12
  13 DESCRIPTION="A pipe to browser utility for use at the shell and within editors like Vim or Emacs"
  14 HOMEPAGE="https://github.com/rtomayko/bcat"
  15
  16 LICENSE="MIT"
  17 SLOT="0"
  18 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
  19 IUSE=""
  20
  21 # Collides on /usr/bin/bcat, bug 418301
  22 RDEPEND="${RDEPEND} !!<app-accessibility/speech-tools-2.1-r3"
  23
  24 ruby_add_bdepend "doc? ( app-text/ronn )"
  25
  26 ruby_add_rdepend "dev-ruby/rack"
  27
  28 each_ruby_prepare() {
  29         sed -i -e "s/a2h/#{ENV['RUBY']} -S a2h/" test/test_bcat_a2h.rb || die
  30 }
  31
  32 each_ruby_test() {
  33         # The Rakefile uses weird trickery with load path that causes gems
  34         # not to be found. Run tests directly instead and do the trickery
  35         # here to support popen calls for the bins in this package.
  36         RUBY=${RUBY} RUBYLIB=lib:${RUBYLIB} PATH=bin:${PATH} ${RUBY} -S testrb test/test_*.rb || die
  37 }
  38
  39 all_ruby_install() {
  40         all_fakegem_install
  41
  42         doman man/*.1
  43 }