dev-qt/qtwidgets/qtwidgets-5.12.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 QT5_MODULE="qtbase"
   6 inherit qt5-build
   7
   8 DESCRIPTION="Set of components for creating classic desktop-style UIs for the Qt5 framework"
   9
  10 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  11         KEYWORDS="arm x86"
  12 fi
  13
  14 # keep IUSE defaults in sync with qtgui
  15 IUSE="gles2 gtk +png +xcb"
  16
  17 DEPEND="
  18         ~dev-qt/qtcore-${PV}
  19         ~dev-qt/qtgui-${PV}[gles2=,png=,xcb?]
  20         gtk? (
  21                 ~dev-qt/qtgui-${PV}[dbus]
  22                 x11-libs/gtk+:3
  23                 x11-libs/libX11
  24                 x11-libs/pango
  25         )
  26 "
  27 RDEPEND="${DEPEND}"
  28
  29 QT5_TARGET_SUBDIRS=(
  30         src/tools/uic
  31         src/widgets
  32         src/plugins/platformthemes
  33 )
  34
  35 QT5_GENTOO_CONFIG=(
  36         gtk:gtk3:
  37         ::widgets
  38         !:no-widgets:
  39 )
  40
  41 QT5_GENTOO_PRIVATE_CONFIG=(
  42         :widgets
  43 )
  44
  45 src_configure() {
  46         local myconf=(
  47                 -opengl $(usex gles2 es2 desktop)
  48                 $(qt_use gtk)
  49                 -gui
  50                 $(qt_use png libpng system)
  51                 -widgets
  52                 $(qt_use xcb xcb system)
  53                 $(usex xcb '-xcb-xlib -xcb-xinput -xkb -xkbcommon' '')
  54         )
  55         qt5-build_src_configure
  56 }