dev-qt/qtwebengine/qtwebengine-5.14.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python2_7 )
   7 inherit multiprocessing python-any-r1 qt5-build
   8
   9 DESCRIPTION="Library for rendering dynamic web content in Qt5 C++ and QML applications"
  10
  11 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  12         KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  13 fi
  14
  15 IUSE="alsa bindist designer geolocation jumbo-build pulseaudio +system-ffmpeg +system-icu widgets"
  16 REQUIRED_USE="designer? ( widgets )"
  17
  18 RDEPEND="
  19         app-arch/snappy:=
  20         dev-libs/glib:2
  21         dev-libs/nspr
  22         dev-libs/nss
  23         ~dev-qt/qtcore-${PV}
  24         ~dev-qt/qtdeclarative-${PV}
  25         ~dev-qt/qtgui-${PV}
  26         ~dev-qt/qtnetwork-${PV}
  27         ~dev-qt/qtprintsupport-${PV}
  28         ~dev-qt/qtwebchannel-${PV}[qml]
  29         dev-libs/expat
  30         dev-libs/libevent:=
  31         dev-libs/libxml2[icu]
  32         dev-libs/libxslt
  33         dev-libs/re2:=
  34         media-libs/fontconfig
  35         media-libs/freetype
  36         media-libs/harfbuzz:=
  37         media-libs/lcms:2
  38         media-libs/libjpeg-turbo:=
  39         media-libs/libpng:0=
  40         >=media-libs/libvpx-1.5:=[svc]
  41         media-libs/libwebp:=
  42         media-libs/mesa[egl,X(+)]
  43         media-libs/opus
  44         sys-apps/dbus
  45         sys-apps/pciutils
  46         sys-libs/zlib[minizip]
  47         virtual/libudev
  48         x11-libs/libdrm
  49         x11-libs/libX11
  50         x11-libs/libXcomposite
  51         x11-libs/libXcursor
  52         x11-libs/libXdamage
  53         x11-libs/libXext
  54         x11-libs/libXfixes
  55         x11-libs/libXi
  56         x11-libs/libXrandr
  57         x11-libs/libXrender
  58         x11-libs/libXScrnSaver
  59         x11-libs/libXtst
  60         alsa? ( media-libs/alsa-lib )
  61         designer? ( ~dev-qt/designer-${PV} )
  62         geolocation? ( ~dev-qt/qtpositioning-${PV} )
  63         pulseaudio? ( media-sound/pulseaudio:= )
  64         system-ffmpeg? ( media-video/ffmpeg:0= )
  65         system-icu? ( >=dev-libs/icu-60.2:= )
  66         widgets? (
  67                 ~dev-qt/qtdeclarative-${PV}[widgets]
  68                 ~dev-qt/qtwidgets-${PV}
  69         )
  70 "
  71 DEPEND="${RDEPEND}
  72         ${PYTHON_DEPS}
  73         >=app-arch/gzip-1.7
  74         dev-util/gperf
  75         dev-util/ninja
  76         dev-util/re2c
  77         sys-devel/bison
  78 "
  79
  80 PATCHES=(
  81         "${FILESDIR}/${P}-disable-fatal-warnings.patch" # bug 695446
  82 )
  83
  84 src_prepare() {
  85         if ! use jumbo-build; then
  86                 sed -i -e 's|use_jumbo_build=true|use_jumbo_build=false|' \
  87                         src/buildtools/config/common.pri || die
  88         fi
  89
  90         # bug 620444 - ensure local headers are used
  91         find "${S}" -type f -name "*.pr[fio]" | xargs sed -i -e 's|INCLUDEPATH += |&$$QTWEBENGINE_ROOT/include |' || die
  92
  93         qt_use_disable_config alsa webengine-alsa src/buildtools/config/linux.pri
  94         qt_use_disable_config pulseaudio webengine-pulseaudio src/buildtools/config/linux.pri
  95
  96         qt_use_disable_mod designer webenginewidgets src/plugins/plugins.pro
  97
  98         qt_use_disable_mod widgets widgets src/src.pro
  99
 100         qt5-build_src_prepare
 101 }
 102
 103 src_configure() {
 104         export NINJA_PATH=/usr/bin/ninja
 105         export NINJAFLAGS="${NINJAFLAGS:--j$(makeopts_jobs) -l$(makeopts_loadavg "${MAKEOPTS}" 0) -v}"
 106
 107         local myqmakeargs=(
 108                 --
 109                 -printing-and-pdf
 110                 -system-opus
 111                 -system-webp
 112                 $(usex alsa '-alsa' '-no-alsa')
 113                 $(usex bindist '-no-proprietary-codecs' '-proprietary-codecs')
 114                 $(usex geolocation '-webengine-geolocation' '-no-webengine-geolocation')
 115                 $(usex pulseaudio '-pulseaudio' '-no-pulseaudio')
 116                 $(usex system-ffmpeg '-system-ffmpeg' '-qt-ffmpeg')
 117                 $(usex system-icu '-webengine-icu' '-no-webengine-icu')
 118         )
 119         qt5-build_src_configure
 120 }
 121
 122 src_install() {
 123         qt5-build_src_install
 124
 125         # bug 601472
 126         if [[ ! -f ${D}${QT5_LIBDIR}/libQt5WebEngine.so ]]; then
 127                 die "${CATEGORY}/${PF} failed to build anything. Please report to https://bugs.gentoo.org/"
 128         fi
 129 }