dev-qt/qtvirtualkeyboard/qtvirtualkeyboard-5.13.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit qt5-build
   6
   7 DESCRIPTION="Customizable input framework and virtual keyboard for Qt"
   8
   9 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  10         KEYWORDS="~arm"
  11 fi
  12
  13 # TODO: unbudle libraries for more layouts
  14 IUSE="handwriting +spell +xcb"
  15
  16 DEPEND="
  17         ~dev-qt/qtcore-${PV}
  18         ~dev-qt/qtdeclarative-${PV}
  19         ~dev-qt/qtgui-${PV}
  20         ~dev-qt/qtsvg-${PV}
  21         spell? ( app-text/hunspell:= )
  22         xcb? ( x11-libs/libxcb:= )
  23 "
  24 RDEPEND="${DEPEND}"
  25
  26 src_configure() {
  27         local myqmakeargs=(
  28                 $(usex handwriting CONFIG+=lipi-toolkit '')
  29                 $(usex spell '' CONFIG+=disable-hunspell)
  30                 $(usex xcb '' CONFIG+=disable-desktop)
  31                 CONFIG+="lang-ar_AR lang-bg_BG lang-cs_CZ lang-da_DK lang-de_DE \
  32                         lang-el_GR lang-en_GB lang-en_US lang-es_ES lang-es_MX \
  33                         lang-et_EE lang-fa_FA lang-fi_FI lang-fr_CA lang-fr_FR \
  34                         lang-he_IL lang-hi_IN lang-hr_HR lang-hu_HU lang-id_ID \
  35                         lang-it_IT lang-ms_MY lang-nb_NO lang-nl_NL lang-pl_PL \
  36                         lang-pt_BR lang-pt_PT lang-ro_RO lang-ru_RU lang-sk_SK \
  37                         lang-sl_SI lang-sq_AL lang-sr_SP lang-sv_SE lang-tr_TR \
  38                         lang-uk_UA lang-vi_VN"
  39         )
  40
  41         qt5-build_src_configure
  42 }