dev-qt/qtsql/qtsql-5.12.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 QT5_MODULE="qtbase"
   6 inherit qt5-build
   7
   8 DESCRIPTION="SQL abstraction library for the Qt5 framework"
   9 SLOT=5/$(ver_cut 1-3) # bug 639140
  10
  11 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  12         KEYWORDS="x86"
  13 fi
  14
  15 IUSE="freetds mysql oci8 odbc postgres +sqlite"
  16
  17 REQUIRED_USE="
  18         || ( freetds mysql oci8 odbc postgres sqlite )
  19 "
  20
  21 DEPEND="
  22         ~dev-qt/qtcore-${PV}
  23         freetds? ( dev-db/freetds )
  24         mysql? ( dev-db/mysql-connector-c:= )
  25         oci8? ( dev-db/oracle-instantclient:=[sdk] )
  26         odbc? ( dev-db/unixODBC )
  27         postgres? ( dev-db/postgresql:* )
  28         sqlite? ( dev-db/sqlite:3 )
  29 "
  30 RDEPEND="${DEPEND}"
  31
  32 QT5_TARGET_SUBDIRS=(
  33         src/sql
  34         src/plugins/sqldrivers
  35 )
  36
  37 QT5_GENTOO_PRIVATE_CONFIG=(
  38         :sql
  39 )
  40
  41 src_configure() {
  42         local myconf=(
  43                 $(qt_use freetds  sql-tds    plugin)
  44                 $(qt_use mysql    sql-mysql  plugin)
  45                 $(qt_use oci8     sql-oci    plugin)
  46                 $(qt_use odbc     sql-odbc   plugin)
  47                 $(qt_use postgres sql-psql   plugin)
  48                 $(qt_use sqlite   sql-sqlite plugin)
  49                 $(usex sqlite -system-sqlite '')
  50         )
  51
  52         use oci8 && myconf+=("-I${ORACLE_HOME}/include" "-L${ORACLE_HOME}/$(get_libdir)")
  53
  54         qt5-build_src_configure
  55 }