dev-qt/qtsingleapplication/qtsingleapplication-2.6.1_p20171024.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_P=qt-solutions-${PV#*_p}
   7 inherit qmake-utils
   8
   9 DESCRIPTION="Qt library to start applications only once per user"
  10 HOMEPAGE="https://code.qt.io/cgit/qt-solutions/qt-solutions.git/"
  11 SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.xz"
  12
  13 LICENSE="|| ( LGPL-2.1 GPL-3 )"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~arm ~hppa ~ppc ~ppc64 x86"
  16 IUSE="doc X"
  17
  18 DEPEND="
  19         dev-qt/qtcore:5
  20         dev-qt/qtlockedfile[qt5(+)]
  21         dev-qt/qtnetwork:5
  22         X? (
  23                 dev-qt/qtgui:5
  24                 dev-qt/qtwidgets:5
  25         )
  26 "
  27 RDEPEND="${DEPEND}"
  28
  29 S="${WORKDIR}/${MY_P}/${PN}"
  30
  31 PATCHES=(
  32         "${FILESDIR}/2.6.1_p20130904-unbundle-qtlockedfile.patch"
  33         "${FILESDIR}/2.6.1_p20130904-no-gui.patch"
  34 )
  35
  36 src_prepare() {
  37         default
  38
  39         echo 'SOLUTIONS_LIBRARY = yes' > config.pri
  40         use X || echo 'QTSA_NO_GUI = yes' >> config.pri
  41
  42         sed -i -e "s/-head/-${PV%.*}/" common.pri || die
  43         sed -i -e '/SUBDIRS+=examples/d' ${PN}.pro || die
  44
  45         # to ensure unbundling
  46         rm src/qtlockedfile* || die
  47 }
  48
  49 src_configure() {
  50         eqmake5
  51 }
  52
  53 src_install() {
  54         use doc && local HTML_DOCS=( doc/html/. )
  55         einstalldocs
  56
  57         # libraries
  58         dolib.so lib/*
  59
  60         # headers
  61         insinto "$(qt5_get_headerdir)"/QtSolutions
  62         doins src/qtsinglecoreapplication.h
  63         use X && doins src/{QtSingleApplication,${PN}.h}
  64
  65         # .prf files
  66         insinto "$(qt5_get_mkspecsdir)"/features
  67         doins "${FILESDIR}"/qtsinglecoreapplication.prf
  68         use X && doins "${FILESDIR}"/${PN}.prf
  69 }