dev-qt/qtprintsupport/qtprintsupport-5.14.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 QT5_MODULE="qtbase"
   6 VIRTUALX_REQUIRED="test"
   7 inherit qt5-build
   8
   9 DESCRIPTION="Printing support library for the Qt5 framework"
  10
  11 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  12         KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
  13 fi
  14
  15 IUSE="cups gles2"
  16
  17 RDEPEND="
  18         ~dev-qt/qtcore-${PV}
  19         ~dev-qt/qtgui-${PV}[gles2=]
  20         ~dev-qt/qtwidgets-${PV}[gles2=]
  21         cups? ( >=net-print/cups-1.4 )
  22 "
  23 DEPEND="${RDEPEND}
  24         test? ( ~dev-qt/qtnetwork-${PV} )
  25 "
  26
  27 QT5_TARGET_SUBDIRS=(
  28         src/printsupport
  29         src/plugins/printsupport
  30 )
  31
  32 QT5_GENTOO_CONFIG=(
  33         cups
  34 )
  35
  36 PATCHES=( "${FILESDIR}/${PN}-5.13.2-no-cups.patch" ) # bug #704936, QTBUG-80945
  37
  38 src_configure() {
  39         local myconf=(
  40                 $(qt_use cups)
  41                 -opengl $(usex gles2 es2 desktop)
  42         )
  43         qt5-build_src_configure
  44 }